x

Feature	Beschreibung	Anwendbar auf
SKIP-LINE*	Fügt eine Leerzeile ein.	HTML (erfordert GRID=OFF) DHTML PDF PS EXL2K EXL07 XLSX
TYPE=SKIPLINE	Formatiert eine Leerzeile.	DHTML PDF PS
UNDER-LINE*	Unterstreicht eine Sortiergruppe.	HTML (erfordert GRID=OFF) DHTML PDF PS
TYPE=UNDERLINE	Formatiert einen Unterstrich.	DHTML PDF PS
STYLE={+|-}UNDERLINE*	Fügt einer Reportkomponente Unterstriche hinzu oder entfernt sie aus Reportkomponenten (außer aus Spaltentiteln).	HTML DHTML PDF PS EXL2K EXL07 XLSX
STYLE={+|-}EXTUNDERLINE*	Verlängert den Unterstrich oder entfernt den Unterstrich aus der gesamten Reportspalte in einem Report mit Styling.	DHTML PDF PS PPT
BAR AS '{-|=}'*	Wählt in einem FML-Report einen dünnen oder dicken Unterstrich aus.	HTML DHTML PDF PS EXL2K

* Wird mit Rand nicht unterstützt.

x

Verwenden Sie nur eine SKIP-LINE pro Reportanfrage.

display_command fieldname SKIP-LINE

oder

{ON|BY} fieldname SKIP-LINE [WHEN expression;]

Hierbei gilt:

display_command

Ist ein Anzeigebefehl.

fieldname

Ist das Anzeige- oder Sortierfeld, nach dem eine Leerzeile eingefügt wird.

Wenn SKIP-LINE mit einem Anzeigefeld verwendet wird, wird nach jeder angezeigten Zeile eine Leerzeile hinzugefügt, wodurch im Prinzip der Report doppelten Zeilenabstand hat. Doppelter Zeilenabstand ist hilfreich, wenn ein Report überprüft wird, da der Leser einfach Anmerkungen neben die individuellen Zeilen schreiben kann.

Wenn SKIP-LINE mit einem Sortierfeld verwendet wird, wird vor jeder Änderung des Werts dieses Feldes eine Leerzeile hinzugefügt. Dies ist eine der wenigen ON-Bedingungen, die nicht nur bei Sortierfeldern (BY) Anwendung finden.

ON|BY

Ist eine vertikale Sortierphrase. Die Begriffe sind synonym.

WHEN-Formel

Gibt bedingte Leerzeilen in der Anzeige eines Reports an, wie es von einer logischen Bedingung vorgegeben wird. Weitere Details zu Formeln finden Sie unter Formeln verwenden.

Nach oben

Beispiel: Eine Leerzeile zwischen Sortiergruppen hinzufügen

Diese Anfrage fügt eine Leerzeile vor jeder Wertänderung des Sortierfelds EMP_ID ein.

DEFINE FILE EMPLOYEE
INCREASE/D8.2M = .05*CURR_SAL;
CURR_SAL/D8.2M=CURR_SAL;
NEWSAL/D8.2M=CURR_SAL + INCREASE;
END
 
TABLE FILE EMPLOYEE
PRINT CURR_SAL OVER INCREASE OVER NEWSAL
BY LOWEST 4 EMP_ID BY LAST_NAME BY FIRST_NAME 
ON EMP_ID SKIP-LINE 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT PDF
END

Die Daten für jeden Angestellten sind hervorgehoben und sind einfach zu lesen:

x

TYPE=SKIPLINE, attribute=value, $

Hierbei gilt:

attribute

Ist ein gültiges StyleSheet-Attribut.

Wert

Ist der Wert des Attributs.

Hinweis: Diese Option wird in PDF-, PS- und HTML-Reports unterstützt (wenn sie mit internen Cascading StyleSheets verwendet wird).

Nach oben

Beispiel: Leerzeilen Farbe hinzufügen

In dieser Anfrage werden Leerzeilen so formatiert, dass sie in der Ausgabe silber angezeigt werden. Die relevante StyleSheet-Deklaration ist in der Anfrage markiert.

SET ONLINE-FMT=PDF
TABLE FILE CENTINV
HEADING
"Low Stock Report"
" "
SUM QTY_IN_STOCK 
WHERE QTY_IN_STOCK LT 5000
BY PRODNAME
ON PRODNAME SKIP-LINE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=SKIPLINE, BACKCOLOR=SILVER, $ 
ENDSTYLE
END

Der Report ist:

x

{ON|BY} fieldname UNDER-LINE [WHEN expression;]

Hierbei gilt:

ON|BY

Ist eine vertikale Sortierphrase. Die Begriffe sind synonym.

fieldname

Ist das Sortierfeld, auf die der Unterstrich zutrifft. UNDER-LINE fügt einen Unterstrich hinzu, wenn sich der Wert des Sortierfeldes ändert. Es wird automatisch ein Unterstrich nach Optionen wie RECAP oder SUB-TOTAL angezeigt, aber er wird vor Seitenumbrüchen angezeigt.

WHEN-Formel

Gibt bedingte Unterstriche in der Anzeige eines Reports an, wie es von einer logischen Bedingung vorgegeben wird. Weitere Details zu Formeln finden Sie unter Formeln verwenden.

Nach oben

Beispiel: Eine Sortiergruppe unterstreichen

Diese Anfrage fügt einen Unterstrich hinzu, wenn sich der Wert des Sortierfeldes BANK_NAME ändert. Sie stellt das Attribut GRID auf OFF ein, wie es von einem HTML-Report erfordert wird.

TABLE FILE EMPLOYEE
PRINT EMP_ID AND BANK_ACCT AND LAST_NAME
BY BANK_NAME 
ON BANK_NAME UNDER-LINE 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Die Daten für jede Bank sind hervorgehoben und sind einfach zu lesen:

x

TYPE=UNDERLINE ... COLOR={color|RGB} (r g b), $

Hierbei gilt:

UNDERLINE

Kennzeichnet Unterstriche, die durch ON fieldname UNDER-LINE erzeugt wurden.

COLOR

Gibt die Farbe des Unterstrichs an. Falls die Anzeige oder das Ausgabegerät keine Farben unterstützt, werden stattdessen Grautöne verwendet. Der Defaultwert ist schwarz.

Farbe

Ist einer der unterstützten Farbwerte. Eine Liste der unterstützten Werte finden Sie unter Farbwerte in einem Report.

RGB

Gibt die Textfarbe als eine Mischung aus rot, grün und blau an.

(r g b)

Ist die gewünschte Farbstärke von rot, grün bzw. blau. Die Werte gehen auf einer Skala von 0 bis 255, wobei 0 am schwächsten und 255 am stärksten ist.

Beachten Sie, dass, wenn Sie die drei Farbkomponenten zu gleichen Teilen verwenden, Grautöne entstehen.

Hinweis: Diese Option wird in PDF-, PS- und HTML-Reports unterstützt (wenn sie mit internen Cascading StyleSheets verwendet wird).

Nach oben

Beispiel: Unterstriche für Sortiergruppen formatieren

In dieser Anfrage wird UNDERLINE verwendet, um die Defaultfarbe für Unterstriche von schwarz zu rot zu ändern.

SET ONLINE-FMT = PDF
TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
HEADING
"Sales Report"
" "
ON CATEGORY UNDER-LINE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=UNDERLINE, COLOR=RED, $ 
ENDSTYLE
END

Sortiergruppenwerte werden so optisch getrennt. Der Online-PDF-Report ist:

x

TYPE=type, [subtype,] STYLE=[+|-]UNDERLINE, $

Hierbei gilt:

type

Ist die Reportkomponente. Gültige Werte finden Sie unter Eine Reportkomponente in einem WebFOCUS StyleSheet identifizieren.

subtype

Zusätzliche Attribute wie COLUMN, ACROSS, ITEM, die benötigt werden, um die Reportkomponente zu identifizieren. Gültige Werte finden Sie unter Eine Reportkomponente in einem WebFOCUS StyleSheet identifizieren.

+

Fügt dem übernommenen Schriftstil einen Unterstrich hinzu oder gibt eine Kombination aus Schriftstilen an (z. B. STYLE=BOLD+UNDERLINE). Dies ist der Defaultwert.

-

Entfernt Unterstriche aus übernommenen Schriftstilen.

x

Diese Syntax gilt für HTML-Reports mit internen Cascading StyleSheets.

TYPE=TITLE, [COLUMN=column,] STYLE=-UNDERLINE, $

Hierbei gilt:

COLUMN=column

Gibt eine Spalte an. Gültige Werte finden Sie unter Eine Reportkomponente in einem WebFOCUS StyleSheet identifizieren.

Nach oben

Beispiel: Unterstriche für Spalten hinzufügen und Unterstriche für Spaltentitel entfernen

Bei dieser Anfrage werden die Werte der Spalte (CATEGORY) unterstrichen und das Default-Unterstreichen der Spaltentitel in einem HTML-Report wird mit einer internen CSS entfernt.

SET HTMLCSS = ON 
TABLE FILE MOVIES
PRINT TITLE DIRECTOR
BY CATEGORY
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=TITLE, STYLE=-UNDERLINE, $
TYPE=REPORT, COLUMN=CATEGORY, STYLE=UNDERLINE, $ 
ENDSTYLE
END

Ein Teil des Reports ist:

x

Per Default reichen Unterstriche für Spaltentitel in einem Report nur vom Anfang bis zum Ende des Spaltentiteltexts. Sie können den Unterstrich verlängern, so dass er über die gesamte Reportspalte in einer Reportausgabe mit Styling reicht, indem Sie die Option EXTUNDERLINE in Ihrem WebFOCUS StyleSheet verwenden. EXTUNDERLINE ist eine Option des STYLE-Attributs für die Reportkomponente TITLE. Sie wird unterstützt für die Formate DHTML, PDF, PS und PPT.

TYPE = TITLE, [COLUMN = colspec,] STYLE = [+|-]EXTUNDERLINE  ,$

Hierbei gilt:

colspec

Ist eine beliebige gültige Spaltenspezifikation.

+EXTUNDERLINE

Fügt dem übernommenen Schriftstil die Option EXTUNDERLINE hinzu oder gibt eine Kombination aus Schriftstilen an (z. B. STYLE=BOLD+UNDERLINE).

-EXTUNDERLINE

Entfernt die Option EXTUNDERLINE aus dem übernommenen Schriftstil.

x

• HTML-Format wird nicht unterstützt, da der Browser die Spaltenbreite berechnet und den Report rendert.
• GRID=ON und EXTUNDERLINE schließen sich gegenseitig aus, da sich die GRID-Linie über die gesamte Breite der Spalte erstreckt. GRID überschreibt das Styling, das für den Spaltentitelunterstrich angegeben wurde.

Nach oben

Beispiel: Einen Unterstrich so verlängern, dass er über die gesamte Reportspalte reicht

Die folgende Anfrage mit der GGSALES-Datenquelle summiert den Dollarumsatz nach Stadt und nach Datum:

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                  
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
END

In der Ausgabe ist zu sehen, dass nur die Spaltentitel unterstrichen sind:

Um eine gesamte Spalte zu unterstreichen, erzeugen Sie die Ausgabe in einem Format, dem Styling hinzugefügt werden kann, und verwenden Sie die Option EXTUNDERLINE im Attribut STYLE für die Komponente TITLE. Beispielsweise erstellt die folgende Anfrage DHTML-Ausgabe, in der die Spaltentitel fettgedruckt und linksbündig sind, und der Unterstrich sich über die gesamte Reportspalte erstreckt:

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                 
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
ON TABLE SET STYLE *  
TYPE=TITLE, STYLE= BOLD +EXTUNDERLINE, JUSTIFY=LEFT, $ 
ENDSTYLE
END

Die Ausgabe ist:

Die folgende Version der Anfrage macht die Optionen EXTUNDERLINE und JUSTIFY=LEFT zum Default für die Komponente TITLE, macht dann den Datumsspaltentitel fettgedruckt und entfernt den verlängerten Unterstrich aus dieser Spalte:

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                   
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
ON TABLE SET STYLE *  
TYPE=TITLE,STYLE= EXTUNDERLINE, JUSTIFY=LEFT ,$   
TYPE=TITLE,COLUMN= DATE, STYLE= -EXTUNDERLINE +BOLD ,$ 
ENDSTYLE                          
END

Die Ausgabe ist:

x

Diese Syntax gilt für HTML-Reports.

BAR [AS '{-|=}'] OVER

Hierbei gilt:

-

Erzeugt einen leichten Unterstrich. Setzen Sie den Bindestrich in einfache Anführungszeichen. Dies ist der Defaultwert.

=

Erzeugt einen starken Unterstrich. Setzen Sie das Gleichheitszeichen in einfache Anführungszeichen.

Nach oben

Beispiel: Den Default-Unterstrich in einem Financial Modeling Language (FML)-Report (HTML) ändern

Diese Anfrage ändert den defaultmäßigen leichten Unterstrich in einen starken Unterstrich in einem FML-Report.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR AS '='                   OVER 
RECAP TOTCASH = R1 + R2 + R3;
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Ein starker Unterstrich trennt Bargeld insgesamt von den detaillierten Daten, wodurch es mehr hervorgehoben wird:

Nach oben

Beispiel: Den Default-Unterstrich in einem Financial Modeling Language (FML)-Report (PDF) ändern

Diese Anfrage ändert den defaultmäßigen einfachen Unterstrich in einem PDF-Report in einen doppelten Unterstrich.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR AS '='                   OVER 
RECAP TOTCASH = R1 + R2 + R3;
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Die Ausgabe ist: