ON TABLE SET HTMLCSS ON

x

Attribut	Beschreibung	Anwendbar auf
GRID	Steuert die Anzeige des Rasters.	HTML
HGRID	Steuert das horizontale Raster und die Dicke der Rasterlinien.	PDF PS
VGRID	Steuert das vertikale Raster und die Dicke der Rasterlinien.	PDF PS

Hinweis: Wenn Sie PDF-Reports mit dem Adobe Reader betrachten, können GRID-Linien dünner erscheinen, wenn die Ansicht nicht auf 100% gestellt ist. Wenn Sie beispielsweise Ihr Dokument mit der Einstellung 50% betrachten, kann es sein, dass manche GRID-Linien dünner sind als andere.

x

[TYPE=REPORT,] GRID= option, $

Hierbei gilt:

TYPE=REPORT

Wendet das Raster auf den gesamten Report an. Ist nicht erforderlich, da es der Default ist.

option

Ist eines des Folgenden:

ON wendet ein Raster auf einen Report an. Wendet Rasterlinien nicht auf Zellen unter einem BY-Feldwert an, bis sich der Wert ändert. Spaltentitel werden nicht unterstrichen. ON ist der Defaultwert.

OFF deaktiviert das Defaultraster. Spaltentitel werden unterstrichen. Sie können Leerzeilen und Unterstriche aufnehmen. Sie können Daten in Zellen nicht umbrechen. Es kann sein, dass der Report mit dieser Einstellung schwieriger zu lesen ist.

FILL wendet Rasterlinien auf alle Zellen des Reports an. Spaltentitel werden nicht unterstrichen.

x

Verwenden Sie für einen einheitlichen Rand die folgende Syntax:

TYPE=type, BORDER=option, [BORDER-STYLE=line_style,]
    [BORDER-COLOR={color|RGB(r g b)},] $

Um unterschiedliche Eigenschaften für obere, untere, linke und/oder rechte Ränder anzugeben, verwenden Sie die folgende Syntax

TYPE=type, BORDER-position=option,
   [BORDER[-position]-STYLE=line_style,]
   [BORDER[-position]-COLOR={color|RGB(r g b)},] $

Hierbei gilt:

type

Identifiziert die Reportkomponente, auf die Ränder angewendet werden. Gültige Werte finden Sie unter Eine Reportkomponente in einem WebFOCUS StyleSheet identifizieren.

option

Kann einer der folgenden Werte sein:

ON aktiviert Ränder. ON erzeugt dieselbe Linie wie MEDIUM.

Hinweis: Die Linieneinstellung MEDIUM stellt sicher, dass die Linien mit den durch GRID-Attribute erstellten Linien identisch sind.

OFF deaktiviert Ränder. OFF ist der Defaultwert.

LIGHT stellt eine dünne Linie ein.

MEDIUM stellt eine mitteldicke Linie ein. ON stellt die Linie auf MEDIUM ein.

HEAVY stellt eine dicke Linie ein.

Breite gibt die Liniendicke in Punkten an, wobei 72 Punkte=1 Zoll. Beachten Sie, dass diese Option mit Excel 2003 nicht unterstützt wird, da es hier nicht die Option gibt, eine Zahl anzugeben, um die Rahmenbreite (Stärke) in Punkten genau anzugeben.

Tipp: Wenn die Linienbreite in Punkten angegeben wird, sehen die Linien in der HTML- und PDF-Ausgabe unterschiedlich aus. Verwenden Sie LIGHT, MEDIUM oder HEAVY, wenn Sie sicherstellen möchten, dass die Linien in allen Anzeigeformaten gleich aussehen.

position

Gibt an, welcher Rand formatiert werden soll. TOP, BOTTOM, LEFT, RIGHT sind gültige Werte.

Sie können für alle BORDER-Attribute Positionskennzeichner angegeben. Sie können so die Linienbreite, die Linienformatierung und die Linienfarbe für den oberen, unteren, rechten und linken Rand einzeln formatieren.

line_style

Stellt die Formatierung für den Rand ein. WebFOCUS-StyleSheets unterstützen alle standardmäßigen CSS-Linienformatierungen. Einige 3D-Formatierungen stehen Ihnen nur in HTML zur Verfügung (mit * gekennzeichnet). Gültige Werte sind:

Formatierung	Beschreibung
NONE	Kein Rand.
SOLID	Durchgezogene Linie.
DOTTED	Gepunktete Linie.
DASHED	Gestrichelte Linie.
DOUBLE	Doppellinie.
GROOVE*	3D-Groove. (Nicht unterstützt mit Excel 2003, was keine Option enthält, um diesen Rahmentyp anzugeben.)
RIDGE*	3D-Ridge. (Nicht unterstützt mit Excel 2003, was keine Option enthält, um diesen Rahmentyp anzugeben.)
INSET*	3D-Inset.
OUTSET*	3D-Outset.

Farbe

Ist einer der voreingestellten Farbwerte. Der Defaultwert ist BLACK (schwarz).

Falls die Anzeige oder das Ausgabegerät keine Farben unterstützt, werden stattdessen Grautöne verwendet. Eine Liste verfügbarer Farben finden Sie unter Reportdaten formatieren.

RGB

Gibt die Schriftfarbe als eine Mischung aus rot, grün und blau an.

(r g b)

Ist die gewünschte Farbstärke von rot, grün bzw. blau. Die Werte gehen auf einer Skala von 0 bis 255, wobei 0 am schwächsten und 255 am stärksten ist. Wenn die drei Farbkomponenten in gleicher Stärke verwendet werden, werden Grautöne angezeigt.

Hinweis: Das Format EXL2K unterstützt den Parameter GRID=ON nicht.

Nach oben

Beispiel: Einen Rand einfügen und formatieren

Diese Anfrage erzeugt einen HTML-Report mit einer dicken roten gepunkteten Linie um die ganze Reportkopfzeile herum.

TABLE FILE GGSALES
SUM BUDUNITS UNITS BUDDOLLARS DOLLARS
BY CATEGORY
ON TABLE SUBHEAD
"</1 Sales Report"
"**CONFIDENTIAL**"
"December 2002 </1"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $ 
TYPE=TABHEADING, STYLE=BOLD, JUSTIFY=CENTER, BORDER=HEAVY,
     BORDER-COLOR=RED, BORDER-STYLE=DOTTED, $ 
ENDSTYLE
END

Die Ausgabe ist:

Tipp: Sie können dieselbe BORDER-Syntax verwenden, um diese Ausgabe in einem PDF- oder PS-Report zu erzeugen.

Nach oben

Beispiel: Das Default-Raster in einem HTML-Report anzeigen

Diese Anfrage verwendet die Default-Einstellung GRID=ON.

TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
ON TABLE SET PAGE-NUM OFF
END

Die Zellen unterhalb des Sortierfeldes CATEGORY haben keine Rasterlinien, bis sich der Wert ändert (z. B. von Kaffee in Essen):

Nach oben

Beispiel: Rasterlinien bei auf alle Zellen in einem HTML-Report anwenden

Diese Anfrage verwendet GRID=FILL, um auf alle Zellen einschließlich der Zellen unterhalb des Sortierfeldes CATEGORY Rasterlinien anzuwenden.

TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=REPORT, GRID=FILL, $ 
ENDSTYLE
END

Alle Zellen haben Rasterlinien:

Nach oben

Beispiel: Ein Raster aus einem HTML-Report entfernen

Diese Anfrage verwendet GRID=OFF, um das Default-Raster aus einem Report zu entfernen.

TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=REPORT, GRID=OFF, $ 
ENDSTYLE
END

Spaltentitel werden unterstrichen:

x

BORDERALL ist die schnellste Methode, um dem gesamten Kopfzeilenraster Rahmen hinzuzufügen. Es können individuelle Rahmen entfernt werden, indem Sie die Rahmen in individuellen Elementen explizit deaktivieren mit BORDER, BORDER-LEFT, BORDER-RIGHT, BORDER-TOP und BORDER-BOTTOM. Für ein gegebenes Element, das eingerahmt ist mit BORDERALL, stellt BORDER-LEFT=OFF das Element ohne linken Rahmen dar, aber es wird der definierte Rahmenstyle beibehalten für den oberen, unteren und den rechten Rahmen.

Es werden drei Ebenen für Rahmen für Kopf- und Fußzeilen unterstützt:

1. Individuelle Zellränder.

   BORDER-LEFT, BORDER-RIGHT, BORDER-TOP und BORDER-BOTTOM können verwendet werden, um die individuellen Komponenten des externen Rahmens der Kopfzeile oder eines ausgewählten Elements oder einer Zelle einzustellen.

2. Alle äußeren Rahmen.

   BORDER= wird verwendet, um die externen Rahmen in einer Kopf- oder Fußzeile einzustellen.

3. Alle äußeren und internen Rahmen.

   BORDERALL wird verwendet, um Rahmeneigenschaften sowohl auf interne als auch externe Rahmen der ausgewählten Kopf- oder Fußzeile anzuwenden.

Hinweis: BORDERALL trifft auf das gesamte Kopf- oder Fußzeilenelement zu. Es kann nicht verwendet werden für individuelle Linien oder Elemente in einem Kopf- oder Fußzeilenelement.

So aktivieren Sie alle externen und internen Rahmen (ein Rahmenraster):

TYPE=headfoot, BORDERALL=option, [BORDER-STYLE=line_style,] [BORDER-COLOR={color|RGB(rgb)},] $

Hierbei gilt:

headfoot

Ist der Kopf- bzw. Fußzeilentyp. TABHEADING, TABFOOTING, HEADING, FOOTING, SUBHEAD und SUBFOOT sind gültige Werte.

Hinweis: BORDERALL trifft auf das gesamte Kopf- oder Fußzeilenelement zu. Es kann nicht verwendet werden für individuelle Linien oder Elemente in einem Kopf- oder Fußzeilenelement.

Verwenden Sie für einen einheitlichen Rand die folgende Syntax:

TYPE=headfoot, BORDER=option

Um unterschiedliche Eigenschaften für obere, untere, linke und/oder rechte Ränder anzugeben, verwenden Sie die folgende Syntax

TYPE=headfoot, BORDER-position=option,
   [BORDER[-position]-STYLE=line_style,]
   [BORDER[-position]-COLOR={color|RGB(rgb)},] $

Hierbei gilt:

headfoot

Identifiziert die Kopfzeile, Fußzeile, Zwischenkopfzeile oder Zwischenfußzeile, auf die Rahmen angewendet werden.

option

Kann einer der folgenden Werte sein:

ON aktiviert Ränder. ON erzeugt dieselbe Linie wie MEDIUM.

Hinweis: Die Linieneinstellung MEDIUM stellt sicher, dass die Linien mit den durch GRID-Attribute erstellten Linien identisch sind.

OFF deaktiviert Ränder. OFF ist der Defaultwert.

LIGHT stellt eine dünne Linie ein.

MEDIUM stellt eine mitteldicke Linie ein. ON stellt die Linie auf MEDIUM ein.

HEAVY stellt eine dicke Linie ein.

Breite gibt die Liniendicke in Punkten an, wobei 72 Punkte=1 Zoll. Beachten Sie, dass diese Option mit Excel 2003 nicht unterstützt wird, da es hier nicht die Option gibt, eine Zahl anzugeben, um die Rahmenbreite (Stärke) in Punkten genau anzugeben.

Tipp: Wenn die Linienbreite in Punkten angegeben wird, sehen die Linien in der HTML- und PDF-Ausgabe unterschiedlich aus. Verwenden Sie LIGHT, MEDIUM oder HEAVY, wenn Sie sicherstellen möchten, dass die Linien in allen Anzeigeformaten gleich aussehen.

position

Gibt an, welcher Rand formatiert werden soll. TOP, BOTTOM, LEFT, RIGHT sind gültige Werte.

Sie können für alle BORDER-Attribute Positionskennzeichner angegeben. Sie können so die Linienbreite, die Linienformatierung und die Linienfarbe für den oberen, unteren, rechten und linken Rand einzeln formatieren.

line_style

Stellt die Formatierung für den Rand ein. WebFOCUS-StyleSheets unterstützen alle standardmäßigen CSS-Linienformatierungen. Einige dreidimensionale Formatierungen stehen Ihnen nur in HTML zur Verfügung (mit * gekennzeichnet). Gültige Werte sind:

Formatierung	Beschreibung
NONE	Kein Rand.
SOLID	Durchgezogene Linie.
DOTTED	Gepunktete Linie.
DASHED	Gestrichelte Linie.
DOUBLE	Doppellinie.
GROOVE*	3D-Groove. (Nicht unterstützt mit Excel 2003, was keine Option enthält, um diesen Rahmentyp anzugeben.)
RIDGE*	3D-Ridge. (Nicht unterstützt mit Excel 2003, was keine Option enthält, um diesen Rahmentyp anzugeben.)
INSET*	3D-Inset.
OUTSET*	3D-Outset.

Hinweis: Alle Zeilentypen, die für PDF unterstützt werden, können für individuelle interne Ränder mit HEADALIGN=BODY verwendet werden.

Farbe

Ist einer der voreingestellten Farbwerte. Der Defaultwert ist BLACK (schwarz).

Falls die Anzeige oder das Ausgabegerät keine Farben unterstützt, werden stattdessen Grautöne verwendet. Eine vollständige Liste der verfügbaren Farbwerte finden Sie unter Farbwerte in einem Report.

RGB

Gibt die Schriftfarbe als eine Mischung aus rot, grün und blau an.

(r g b)

Ist die gewünschte Farbstärke von rot, grün bzw. blau. Die Werte gehen auf einer Skala von 0 bis 255, wobei 0 am schwächsten und 255 am stärksten ist. Wenn die drei Farbkomponenten in gleicher Stärke verwendet werden, werden Grautöne angezeigt.

Nach oben

Beispiel: Rahmen innerhalb von Kopf- und Fußzeilenelementen in PDF-Reportausgabe steuern

Die folgende Anfrage mit der EMPLOYEE-Datenquelle hat eine Seitenkopfzeile, eine Zwischenkopfzeile, eine Zwischenfußzeile und eine Reportfußzeile:

TABLE FILE EMPLOYEE
HEADING
" Department Report Page <TABPAGENO "
PRINT LAST_NAME AS ''
FIRST_NAME AS ''
CURR_SAL AS ''
CURR_JOBCODE AS ''
BY DEPARTMENT AS ''
WHERE CURR_SAL NE 0.0
ON TABLE PCHOLD FORMAT PDF
ON DEPARTMENT SUBFOOT
" "
"Subtotal:<ST.CURR_SAL"
" "
ON DEPARTMENT SUBHEAD
"Department <+0>Last Name <+0>First Name <+0>Salary<+0>Jobcode <+0>"
ON TABLE SUBFOOT
"Grand Total:<ST.CURR_SAL"
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT, FONT=ARIAL, BORDER=ON, SQUEEZE=ON, $
TYPE=REPORT, COLUMN=CURR_JOBCODE,SQUEEZE=.75, $
TYPE = SUBHEAD, HEADALIGN=BODY, BORDERALL=ON,$
TYPE = SUBFOOT, HEADALIGN=BODY,$
TYPE = SUBFOOT, LINE=2, ITEM=1, COLSPAN=3, JUSTIFY=RIGHT,$
TYPE = SUBFOOT, LINE=2, ITEM=2, JUSTIFY=RIGHT,$
TYPE = TABFOOTING, HEADALIGN=BODY,$
TYPE = TABFOOTING, ITEM=1, COLSPAN=3, JUSTIFY=RIGHT,$
TYPE = TABFOOTING, ITEM=2, JUSTIFY=RIGHT,$
END
 

Die REPORT-Komponente hat BORDER=ON, so dass die Seitenkopfzeile einen externen Rahmen hat.

Die Zwischenkopfzeile hat BORDERALL=ON und HEADALIGN=BODY, so dass das Zwischenkopfzeilenraster ausgerichtet ist mit dem Hauptraster, und jedes Element in der Zwischenkopfzeile dargestellt wird als vollständig umrandete individuelle Zelle.

Das StyleSheet richtet die Zwischenfußzeilenelemente mit dem Hauptteil des Reports aus und die Zwischensumme für Gehalt befindet sich auf der zweiten Zeile, ausgerichtet mit der Spalte CURR_SAL.

Die Tabellenfußzeile hat einen Rahmen um die gesamte Fußzeile, da die REPORT-Komponente BORDER=ON angibt. Die Gesamtsumme wird ausgerichtet und bündig angezeigt mit der Spalte CURR_SAL im Report.

Die Ausgabe ist:

x

Derzeit wird mit SQUEEZE=ON der rechte Rand für Zwischenkopfzeilen und Zwischenfußzeilen, basierend auf der maximalen Länge aller Kopfzeilen, Fußzeilen, Zwischenkopfzeilen und Zwischenfußzeilen definiert. Die Länge von Zwischenkopfzeilen und Zwischenfußzeilen ist gebunden an die Länge von Seitenkopfzeilen und Seitenfußzeilen, nicht an die Größe der Datenspalten im Hauptteil des Reports.

Sie können das Attribut ALIGN-BORDERS=BODY in einem StyleSheet verwenden, um die Zwischenkopfzeilen und Zwischenfußzeilen mit dem Hauptteil des Reports in der PDF-Reportausgabe auszurichten, anstatt mit den anderen Kopfzeilenelementen.

Sie können Zwischenkopfzeilen- und Zwischenfußzeilenränder mit dem Hauptteil des Reports ausrichten, indem Sie entweder das Attribut ALIGN-BORDERS=BODY der StyleSheet-Deklaration für die Komponente REPORT hinzufügen, oder es in eine eigene Deklaration ohne ein TYPE-Attribut platzieren.

[TYPE=REPORT,] ALIGN-BORDERS={OFF|BODY} ,$

Hierbei gilt:

OFF

Richtet den rechten Rand von Zwischenkopfzeilen und Zwischenfußzeilen nicht mit dem Reporttext aus.

BODY

Gibt an, dass die Breite von Zwischenkopf- und Zwischenfußzeilen unabhängig ist von Kopfzeilen, Fußzeilen, Tabkopfzeilen und Tabfußzeilen, und dass der rechte Rand des Reporttexts ausgerichtet wird indem entweder Zwischenkopfzeilen oder Zwischenfußzeilen verlängert werden (wenn sie kürzer sind als die Datenspalten) oder indem die Datenspalten verbreitert werden (wenn sie kürzer sind als die maximale Breite von Zwischenkopfzeilen und Zwischenfußzeilen).

x

Ohne das Attribut ALIGN-BORDERS=BODY wird die Breite der Zwischenkopfzeilen und Zwischenfußzeilen bestimmt von der breitesten Kopf- oder Fußzeile (Report, Seite, Zwischenkopfzeilen und Zwischenfußzeilen).

In der folgenden Abbildung sehen Sie Reportausgabe ohne das Attribut ALIGN-BORDERS=BODY.

Wenn die Textzeilen breiter sind als die Zwischenkopfzeilen und Zwischenfußzeilen, werden der Rand und die Hintergrundfarbe der Zwischenkopfzeilen und Zwischenfußzeilen breiter gemacht, um der Breite der Datenzeilen zu entsprechen, wie es in der folgenden Reportausgabe zu sehen ist.

Wenn die Zwischenkopfzeilen und Zwischenfußzeilen länger sind als die Textzeilen, wird jeder Datenzeile eine zusätzliche Füllzelle hinzugefügt, um zu ermöglichen, dass die definierten Ränder und Hintergrundfarben die von den Zwischenkopfzeilen und Zwischenfußzeilen definierte Breite ausfüllen, wie es in der folgenden Reportausgabe zu sehen ist.

ALIGN-BORDERS=BODY wurde konzipiert, um zu funktionieren mit:

• Reports mit einem Panel (Reports, in denen Panels nicht horizontal angeordnet werden).
• Mit Panels versehene Reports, für die HEADPANEL aktiviert wurde für alle im Report definierten Zwischenkopfzeilen und Zwischenfußzeilen.

  Wenn HEADPANEL ON eingestellt wurde, werden die Kopf- und Fußzeilen von der ersten Seite eines mit Panels versehenen Reports in den nachfolgenden Panels repliziert. Wenn HEADPANEL nicht verwendet wird, können Inhalte in die mit Panels versehenen Kopfzeilen platziert werden, indem Sie Elemente mit dem StyleSheet-Attribut POSITION explizit innerhalb der Kopfzeilen platzieren. Unter diesen Umständen wird ALIGN-BORDERS=BODY ignoriert.

  Daher richtet ALIGN-BORDERS=BODY, wenn HEADPANEL auf der Reportebene aktiviert ist und nicht explizit für eine der individuellen Zwischenkopf- oder Zwischenfußzeilen deaktiviert wurde, oder wenn es explizit für alle Zwischenkopf- und Zwischenfußzeilen aktiviert wurde, die Ränder aller Zwischenkopf- und Zwischenfußzeilen mit den Daten aus. Andernfalls kommt es zum Default-Verhalten, bei dem mit den Seitenkopfzeilen und Seitenfußzeilen ausgerichtet wird.

Nach oben

Beispiel: Zwischenkopfzeilen- und Zwischenfußzeilenränder in einem PDF-Report mit einem Panel ausrichten

Die folgende Anfrage mit der Datenquelle GGSALES hat eine Reportkopfzeile, Reportfußzeile, Seitenkopfzeile, Seitenfußzeile und eine Zwischenkopfzeile für jede Region. Die Ränder der Zwischenkopfzeilen und Zwischenfußzeilen sind nicht ausgerichtet (ALIGN-BORDERS=OFF ,$):

DEFINE FILE GGSALES
SHOWCATPROD/A30 = CATEGORY || (' / ' | PRODUCT);
END
TABLE FILE GGSALES
SUM 
     DOLLARS/I8M AS ''
BY REGION
BY ST
BY CITY
ACROSS SHOWCATPROD AS 'Product Sales'
     
ON REGION SUBHEAD
" "
"Subheading <+0>Region <REGION<+0> "
" "
ON REGION SUBTOTAL AS '*TOTAL'
ON TABLE SUBHEAD
"Report Heading"
" "
"TYPE=REPORT, ALIGN-BORDERS=OFF, BORDER=ON, $"
HEADING
"Page Heading "
" "
" "
" "
FOOTING
" "
"Page Footing<+0>Page <TABPAGENO "
ON TABLE SUBFOOT
" "
"Report Footing"

WHERE CATEGORY EQ 'Coffee';
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
    TYPE=REPORT,
     FONT='ARIAL',
     SIZE=9,
     LEFTMARGIN=.75,
     RIGHTMARGIN=.5,
     TOPMARGIN=.1,
     BOTTOMMARGIN=.1,
     ALIGN-BORDERS=OFF,
     BORDER=ON,
     SQUEEZE=ON,$
$
TYPE=TITLE,
     STYLE=BOLD,
$
TYPE=TABHEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=TABHEADING,
     LINE=3,
     JUSTIFY=CENTER,
$
TYPE=TABFOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     IMAGE=smplogo1.gif,
     POSITION=(+4.6000000 +0.03000000),
     JUSTIFY=RIGHT,
$
TYPE=FOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=FOOTING,
   LINE=2,
   ITEM=2,
   OBJECT=TEXT,
   POSITION=6.3,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
  LINE=2,
  ITEM=3,
  OBJECT=TEXT,
  POSITION=2.5,
$
TYPE=SUBFOOT,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBTOTAL,
     BACKCOLOR=RGB(210 210 210),
$
TYPE=ACROSSVALUE,
     SIZE=9,
     WRAP=ON,
$
TYPE=ACROSSTITLE,
     STYLE=BOLD,
$
TYPE=GRANDTOTAL,
     BACKCOLOR=RGB(210 210 210),
     STYLE=BOLD,
$
ENDSTYLE
END

In der Ausgabe sehen Sie, dass die Zwischenkopfzeilenränder mit der Kopfzeile ausgerichtet werden, und nicht mit dem Reporttext.

Ändern Sie jetzt das Attribut ALIGN-BORDERS in ALIGN-BORDERS=BODY und führen Sie die Anfrage erneut aus. Die Zwischenkopfzeilen werden jetzt mit dem Reporttext ausgerichtet, wie es in der folgenden Abbildung zu sehen ist.

Nach oben

Beispiel: Zwischenkopfzeilen- und Zwischenfußzeilenränder in einem Report mit mehreren Panels ausrichten

Die folgende Anfrage hat HEADPANEL=ON für alle Kopf- und Fußzeilen. Sie hat auch das Attribut ALIGN-BORDERS=BODY:

SET BYPANEL=ON
DEFINE FILE GGSALES
SHOWCATPROD/A30 = CATEGORY || (' / ' | PRODUCT);
END
TABLE FILE GGSALES
SUM 
     DOLLARS/I8M AS ''
BY REGION
BY ST
BY CITY
ACROSS SHOWCATPROD AS 'Product Sales'
     
ON REGION SUBHEAD
" "
"Subheading <+0>Region <REGION<+0> "
" "
ON REGION SUBTOTAL AS '*TOTAL'
ON TABLE SUBHEAD
"Report Heading"
" "
"TYPE=REPORT, ALIGN-BORDERS=BODY, HEADPANEL=ON, BORDER=ON, $"
HEADING
"Page Heading "
" "
" "
" "
FOOTING
" "
"Page Footing<+0>Page <TABPAGENO "
ON TABLE SUBFOOT
" "
"Report Footing"

WHERE CATEGORY NE 'Coffee';
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     FONT='ARIAL',
     SIZE=9,
     LEFTMARGIN=.75,
     RIGHTMARGIN=.5,
     TOPMARGIN=.1,
     BOTTOMMARGIN=.1,
     HEADPANEL=ON,
     ALIGN-BORDERS=BODY,
     BORDER=ON,
$
TYPE=TITLE,
     STYLE=BOLD,
$
TYPE=TABHEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=TABHEADING,
     LINE=3,
     JUSTIFY=CENTER,
$
TYPE=TABFOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     IMAGE=smplogo1.gif,
     POSITION=(+4.6000000 +0.03000000),
     JUSTIFY=RIGHT,
$
TYPE=FOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=FOOTING,
   LINE=2,
   ITEM=2,
   OBJECT=TEXT,
   POSITION=6.3,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
   LINE=2,
   ITEM=3,
   OBJECT=TEXT,
   POSITION=2.5,
$
TYPE=SUBFOOT,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBTOTAL,
     BACKCOLOR=RGB(210 210 210),
$
TYPE=ACROSSVALUE,
     SIZE=9,
     WRAP=ON,
$
TYPE=ACROSSTITLE,
     STYLE=BOLD,
$
TYPE=GRANDTOTAL,
     BACKCOLOR=RGB(210 210 210),
     STYLE=BOLD,
$
ENDSTYLE
END

In der Ausgabe ist zu sehen, dass die Zwischenkopfzeilen ausgerichtet sind mit den Daten im jeweiligen Panel.

x

Diese Syntax ist für PDF- oder PS-Reports.

TYPE=type, {HGRID|VGRID}={ON|OFF|HEAVY}, $

Hierbei gilt:

type

Identifiziert die Reportkomponente, auf die Rasterlinien angewendet werden. Gültige Werte finden Sie unter Eine Reportkomponente in einem WebFOCUS StyleSheet identifizieren.

HGRID

Gibt horizontale Rasterlinien an.

VGRID

Gibt vertikale Rasterlinien an.

ON

Wendet dünne Rasterlinien an.

OFF

Unterdrückt die Rasterlinien. OFF ist der Defaultwert.

HEAVY

Wendet dicke Rasterlinien an.

Nach oben

Beispiel: Rasterlinien bei Reportdaten (PDF) anwenden

Diese Anfrage wendet dünne horizontale Rasterlinien auf Reportdaten an.

SET ONLINE-FMT = PDF
TABLE FILE GGDEMOG
HEADING
"State Statistics"
" "
SUM HH AS 'Number of,Households' AVGHHSZ98 AS 'Avg.,Size'
MEDHHI98 AS 'Avg.,Income'
BY ST
WHERE ST EQ 'CA' OR 'FL' OR 'NY'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=DATA, HGRID=ON, $ 
END

Im PDF-Report erleichtern die Linien die Differenzierung von Daten nach Staat: