Eine strukturierte HOLD-Datei erstellen

Strukturierte HOLD-Dateien erleichtern die Migration von Datenquellen und Reports zwischen Betriebsumgebungen.

Andere HOLD-Formate zeichnen Daten aus den ursprünglichen Quellen auf und behalten ggf. ein paar implizite strukturelle Elemente aus der Anfrage selbst bei. Sie geben jedoch die meisten Informationen über die ursprünglichen Datenquellen und ihre Beziehungen mit der HOLD-Masterdatei oder Datenquelle nicht weiter. Strukturierte HOLD-Dateien extrahieren jedoch die Daten in eine Struktur, die den ursprünglichen Datenquellen entspricht. Nachfolgende Anfragen, die an die HOLD-Datei gestellt werden, können diese beibehaltenen Datenbeziehungen verwenden, um dieselben Arten Datenbeziehungenen in anderen Umgebungen oder in anderen Datenquellentypen wiederherzustellen.

Eine strukturierte HOLD-Datei kann in den Formaten ALPHA, BINARY oder FOCUS erstellt werden:

Die HOLD-Datei enthält immer alle ursprünglichen Segmentinstanzen, die basierend auf der TABLE-Anfrage für einen vollständigen Report nötig sind. Unabhängig davon, welcher Anzeigebefehl in der ursprünglichen Anfrage verwendet wurde (PRINT, LIST, SUM, COUNT), wird die strukturierte HOLD-Datei so erstellt, als ob PRINT verwendet worden wäre. Aggregation wird ignoriert.

Die HOLD-Datei enthält entweder alle Felder in der Struktur, die in der Anfrage angegeben sind und verwendet werden, um die Anfrage zu erfüllen, oder alle Anzeigefelder und BY-Felder. Die Datei enthält keine DEFINE-Felder, auf die in der Anfrage nicht ausdrücklich verwiesen wird. Sie enthält alle Felder, die benötigt werden, um alle DEFINE-Felder zu überprüfen, auf die in der Anfrage verwiesen wird.

Strukturierte HOLD-Dateien werden nur von den Befehlen TABLE und TABLEF unterstützt. Sie können überall erstellt werden, wo HOLD-Dateien unterstützt werden. Sie müssen strukturierte HOLD-Dateien in einer bestimmten Anfrage aktivieren, indem Sie in der Anfrage den ON TABLE SET EXTRACT-Befehl ausgeben, bevor Sie die strukturierte HOLD-Datei erstellen.

Syntax: Strukturierte HOLD-Dateien für eine Anfrage aktivieren

ON TABLE SET EXTRACT {ON|*|OFF}

Hierbei gilt:

ON: Aktiviert strukturierte HOLD-Dateien für diese Anfrage und extrahiert alle Felder, die in der Anfrage genannt werden.
*: Aktiviert strukturierte HOLD-Dateien für diese Anfrage und gibt an, dass ein Block mit Extrahierungsoptionen folgt. Sie können beispielsweise bestimmte Felder aus der strukturierten HOLD-Datei ausschließen. Informationen hierzu finden Sie unter Optionen für das Erzeugen von strukturierten HOLD-Dateien angeben.
OFF: Deaktiviert strukturierte HOLD-Dateien für diese Anfrage. OFF ist der Defaultwert.

Syntax: Eine strukturierte HOLD-Datei erstellen

Aktivieren Sie, bevor Sie den HOLD-Befehl ausgeben, strukturierte HOLD-Dateien für die Anfrage, indem Sie den ON TABLE SET EXTRACT-Befehl ausgeben, der unter Strukturierte HOLD-Dateien für eine Anfrage aktivieren beschrieben ist. Geben Sie dann den HOLD-Befehl aus, um die strukturierte HOLD-Datei zu erstellen:

[ON TABLE] {HOLD|PCHOLD} [AS name] FORMAT {ALPHA|BINARY|FOCUS}

Hierbei gilt:

name: Ist der Name der HOLD-Datei. Der Name ist, wenn er weggelassen wird, per Default HOLD.
FORMAT: Ist ALPHA, BINARY oder FOCUS.

Hinweis: Sie können einen SET-Befehl ausgeben, um das Default-HOLD-Format entweder auf ALPHA oder BINARY einzustellen:

SET HOLDFORMAT=ALPHA
SET HOLDFORMAT=BINARY

Syntax: Optionen für das Erzeugen von strukturierten HOLD-Dateien angeben

Verwenden Sie, um Optionen für die Extrahierung wie das Ausschließen bestimmter Felder anzugeben, die *-Option des SET EXTRACT-Befehls:

ON TABLE SET EXTRACT *
EXCLUDE = (fieldname1, fieldname2, fieldname3 , ..., fieldnamen),$
FIELDS={ALL|EXPLICIT},$
ENDEXTRACT
ON TABLE HOLD AS name FORMAT {ALPHA|BINARY|FOCUS}

Hierbei gilt:

EXCLUDE=(fieldname1, fieldname2, fieldname3,..., fieldnamen): Schließt die angegebenen Felder aus der HOLD-Datei aus.
,$: Ist die für das Begrenzen von Elementen im Extrahierungsblock erforderliche Syntax.
ALL: Enthält alle realen Felder und alle DEFINE-Felder, die verwendet werden, um die Anfrage auszuführen.
EXPLICIT: Enthält nur die realen Felder und DEFINE-Felder aus der Anzeigeliste oder der Auflistung BY-Sortierfeld. DEFINE-Felder, auf die nicht explizit verwiesen wird und Felder, die verwendet werden, um DEFINEs zu überprüfen, sind nicht enthalten.
ENDEXTRACT: Beendet die Extrahierungs-Utility

Nach oben

Beispiel: Eine strukturierte HOLD-Datei im ALPHA-Format herstellen

TABLE FILE EMPLOYEE
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
ON TABLE SET EXTRACT ON
ON TABLE HOLD FORMAT ALPHA
END

Diese Anfrage erzeugt die folgende HOLD-Masterdatei:

FILENAME=HOLD    , SUFFIX=FIX     , $
  SEGMENT=EMPINFO, SEGTYPE=S0, $
    FIELDNAME=RECTYPE, ALIAS=R, USAGE=A3, ACTUAL=A3, $
    FIELDNAME=LAST_NAME, ALIAS='LN', USAGE=A15, ACTUAL=A15, $
    FIELDNAME=FIRST_NAME, ALIAS='FN', USAGE=A10, ACTUAL=A10, $
    FIELDNAME=DEPARTMENT, ALIAS='DPT', USAGE=A10, ACTUAL=A10, $
    FIELDNAME=ED_HRS, ALIAS='OJT', USAGE=F6.2, ACTUAL=A06, $
  SEGMENT=PAYINFO, SEGTYPE=S0, PARENT=EMPINFO, $
    FIELDNAME=RECTYPE, ALIAS=1, USAGE=A3, ACTUAL=A3, $
    FIELDNAME=SALARY, ALIAS='SAL', USAGE=D12.2M, ACTUAL=A12, $
    FIELDNAME=JOBCODE, ALIAS='JBC', USAGE=A3, ACTUAL=A03, $

Beachten Sie das RECTYPE-Feld, das für strukturierte HOLD-Dateien im ALPHA- oder BINARY-Format erzeugt wird. Jeder Datensatz in der HOLD-Datei fängt mit dem RECTYPE an, um anzuzeigen, zu welchem Segment er in der ursprünglichen Struktur gehört hat. Das Rootsegment hat RECTYPE=R. Die RECTYPEs der anderen Segmente sind sequentielle Nummern, die von oben nach unten und links nach rechts zugewiesen werden.

Im Folgenden sind die ersten paar Datensätze in der HOLD-Datei aufgelistet:

R  STEVENS        ALFRED    PRODUCTION 25.00
1      11000.00A07
1      10000.00A07
R  SMITH          MARY      MIS        36.00
1      13200.00B14
R  JONES          DIANE     MIS        50.00
1      18480.00B03
1      17750.00B02
R  SMITH          RICHARD   PRODUCTION 10.00
1       9500.00A01
1       9050.00B01

Nach oben

Beispiel: Eine strukturierte HOLD-Datei im FOCUS-Format erstellen

TABLE FILE EMPLOYEE
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
ON TABLE SET EXTRACT ON
ON TABLE HOLD FORMAT FOCUS
END

Diese Anfrage erzeugt die folgende HOLD-Masterdatei:

FILENAME=HOLD    , SUFFIX=FOC     , $
  SEGMENT=EMPINFO, SEGTYPE=S0, $
    FIELDNAME=LAST_NAME, ALIAS='LN', USAGE=A15, $
    FIELDNAME=FIRST_NAME, ALIAS='FN', USAGE=A10, $
    FIELDNAME=DEPARTMENT, ALIAS='DPT', USAGE=A10, $
    FIELDNAME=ED_HRS, ALIAS='OJT', USAGE=F6.2, $
  SEGMENT=PAYINFO, SEGTYPE=S0, PARENT=EMPINFO, $
    FIELDNAME=SALARY, ALIAS='SAL', USAGE=D12.2M, $
    FIELDNAME=JOBCODE, ALIAS='JBC', USAGE=A3, $

Nach oben

Beispiel: Eine strukturierte HOLD-Datei wiederherstellen

Die folgende Anfrage stellt die ursprüngliche FOCUS-Datenquelle aus der strukturierten HOLD-Datei wieder her, die in Eine strukturierte HOLD-Datei im ALPHA-Format herstellen erstellt wurde:

TABLE FILE HOLD
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
ON TABLE SET EXTRACT ON
ON TABLE HOLD AS RECONST FORMAT FOCUS
END

Diese Anfrage erzeugt die folgende Masterdatei:

FILENAME=RECONST    , SUFFIX=FOC     , $
  SEGMENT=EMPINFO, SEGTYPE=S0, $
    FIELDNAME=LAST_NAME, ALIAS='LN', USAGE=A15, $
    FIELDNAME=FIRST_NAME, ALIAS='FN', USAGE=A10, $
    FIELDNAME=DEPARTMENT, ALIAS='DPT', USAGE=A10,
    FIELDNAME=ED_HRS, ALIAS='OJT', USAGE=F6.2, $
  SEGMENT=PAYINFO, SEGTYPE=S0, PARENT=EMPINFO, $
    FIELDNAME=SALARY, ALIAS='SAL', USAGE=D12.2M, $
    FIELDNAME=JOBCODE, ALIAS='JBC', USAGE=A3, $

Die folgende Anfrage druckt die Reportausgabe:

TABLE FILE RECONST
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
END

Die Ausgabe ist:

DEPARTMENT           SALARY  LAST_NAME        FIRST_NAME  JOBCODE  ED_HRS
----------           ------  ---------        ----------  -------  ------
MIS              $27,062.00  CROSS            BARBARA     A17       45.00
                 $25,775.00  CROSS            BARBARA     A16       45.00
                 $21,780.00  BLACKWOOD        ROSEMARIE   B04       75.00
                 $18,480.00  JONES            DIANE       B03       50.00
                             MCCOY            JOHN        B02         .00
                 $17,750.00  JONES            DIANE       B02       50.00
                 $13,200.00  SMITH            MARY        B14       36.00
                  $9,000.00  GREENSPAN        MARY        A07       25.00
                  $8,650.00  GREENSPAN        MARY        B01       25.00
PRODUCTION       $29,700.00  BANNING          JOHN        A17         .00
                 $26,862.00  IRVING           JOAN        A15       30.00
                 $24,420.00  IRVING           JOAN        A14       30.00
                 $21,120.00  ROMANS           ANTHONY     B04        5.00
                 $16,100.00  MCKNIGHT         ROGER       B02       50.00
                 $15,000.00  MCKNIGHT         ROGER       B02       50.00
                 $11,000.00  STEVENS          ALFRED      A07       25.00
                 $10,000.00  STEVENS          ALFRED      A07       25.00
                  $9,500.00  SMITH            RICHARD     A01       10.00
                  $9,050.00  SMITH            RICHARD     B01       10.00

Nach oben

Beispiel: Felder aus strukturierten HOLD-Dateien ausschließen

Diese Anfrage schließt das SALARY-Feld aus, das für die Erstellung der Sequenz verwendet wird.

TABLE FILE EMPLOYEE
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
ON TABLE SET EXTRACT *
EXCLUDE=(SALARY),$
ENDEXTRACT
ON TABLE HOLD FORMAT FOCUS
END

Diese Anfrage erzeugt die folgende HOLD-Masterdatei:

FILENAME=HOLD   , SUFFIX=FOC     , $
  SEGMENT=EMPINFO, SEGTYPE=S0, $
    FIELDNAME=LAST_NAME, ALIAS='LN', USAGE=A15, $
    FIELDNAME=FIRST_NAME, ALIAS='FN', USAGE=A10, $
    FIELDNAME=DEPARTMENT, ALIAS='DPT', USAGE=A10, $
    FIELDNAME=ED_HRS, ALIAS='OJT', USAGE=F6.2, $
  SEGMENT=PAYINFO, SEGTYPE=S0, PARENT=EMPINFO, $
    FIELDNAME=JOBCODE, ALIAS='JBC', USAGE=A3, $

Referenz: Elemente, die in einer strukturierten HOLD-Datei enthalten sind

Strukturierte HOLD-Dateien enthalten alle ursprünglichen Segmenteinstanzen, die für die TABLE- oder TABLEF-Anfrage benötigt werden. Unabhängig davon, welcher Anzeigebefehl in der ursprünglichen Anfrage verwendet wurde (PRINT, LIST, SUM oder COUNT), wird die strukturierte HOLD-Datei so erstellt, als ob PRINT verwendet worden wäre.

Die Extrahierungsdatei enthält die folgenden Elemente:

Alle realen Felder, die in der Anfrage genannt werden, wie Anzeigeobjekte, Sortierfelder und Felder, die in Auswahlkriterien verwendet werden (WHERE/IF-Tests).
Beachten Sie, dass Felder, auf die in einer Anfrage mehrmals verwiesen wird, in der HOLD-Datei nur einmal vorkommen.
Felder, die in der Bedingung FILTER FILE verwendet werden.
Es werden alle Präfixoperatoren außer ALL ignoriert. (dadurch wird lediglich die Datenmenge beeinträchtigt, jedoch keine Berechnung impliziert).
Auf Feldern basierende Neuformatierung (FIELD1/FIELD2=) führt dazu, dass das ursprüngliche Feld und das formatierte Feld enthalten sind.
Ein GROUP-Feld, wenn darauf explizit verwiesen wird, oder wenn in der Anfrage auf alle seine Elemente verwiesen wird.
Hinweis: Wenn ein spezifisches Element der Gruppe ausgeschlossen ist (EXCLUDE) oder auf dieses nicht verwiesen wird, wird seine GROUP der Extrahierungsmasterdatei nicht hinzugefügt (dies gilt auch für eingebettete und überlappende Gruppen). Wenn eine GROUP und alle ihre Elemente in einer Anfrage genannt werden, wird die GROUP der Extrahierungsdatei HOLD nicht als reales Feld hinzugefügt.
Bei FIELDS=ALL werden alle DEFINE-Felder, die in der Anfrage verwendet werden, in der strukturierten HOLD-Datei zu realen Feldern und werden zusammen mit anderen Feldern aufgenommen, die in der DEFINE-Formel verwendet werden (einschließlich anderer DEFINE-Felder). Verwenden Sie EXCLUDE, um die Anzahl der in der EXTRACT-Ausgabe enthaltenen Felder zu reduzieren.
Bei FIELDS=EXPLICIT sind Anzeigeobjekte und Sortierfelder enthalten. DEFINE-Felder werden zu realen Feldern, wenn auf sie in der Anfrage verwiesen wird. Felder, die verwendet werden, um sie zu erstellen, sind jedoch nicht enthalten, es sei denn, es wird explizit auf sie verwiesen. Es wird dadurch die Anzahl der Felder reduziert, die in der Anfrage zurückgegeben werden.

Referenz: Elemente, die in einer strukturierten HOLD-Datei nicht enthalten sind

Präfixoperatoren von WHERE-Feldern werden zwar bei der Datenauswahl überprüft, sind jedoch nicht in der extrahierten Ausgabe enthalten.
Es werden Präfixoperatoren von Anzeigeobjekten ignoriert (außer ALL).
Wenn in MATCH-, MORE- und GRAPH-Anfragen Syntax für strukturierte HOLD-Dateien verwendet wird, führt dies zu Fehlermeldungen und die Prozedur wird beendet.
WHERE/IF TOTAL-Tests werden von Anfragen für strukturierte HOLD-Dateien nicht unterstützt und führen zum Abbruch der Anfrage.
Die Neuformatierung realer Felder wird ignoriert (es ist nur das reale Feld enthalten).
Berechnete Felder sind nicht enthalten. Felder, die in COMPUTE-Formeln verwendet werden, sind in der Extrahierungsdatei jedoch enthalten.

Referenz: Hinweise zu Struktur und Verhalten

Anfragen für strukturierte HOLD-Dateien unterliegen denselben Einschränkungen bezüglich der Anzahl und Größe von Feldern wie alle anderen TABLE-Anfragen.

Hinweise zur Struktur

Die folgenden SET-Parameter werden in Anfragen an strukturierte HOLD-Dateien ausgeschaltet oder ignoriert:
- AUTOINDEX
- AUTOPATH
- AUTOSTRATEGY
- EXTHOLD
- EXTSORT
- HOLDATTR
- Alle SET- und ON TABLE SET-Befehle, die verwendet werden, um das Ausgabeformat zu steuern, werden bei der Erstellung der Extrahierungsdatei ignoriert.
Alternative Ansichten werden beachtet und in der Struktur der Extrahierungsdatei widergespiegelt.
Indizierte Ansichten, die in der Anfrage angegeben werden, werden beachtet und in der Struktur der Ausgabedatei widergespiegelt.
Wenn eine Anfrage eine Datei erzeugen würde, die zwei unabhängige verwaiste Segmente enthält, da das übergeordnete Segment ausgeschlossen wurde, wird ein Dummy-Systemsegment erstellt, das als übergeordnetes Segment der beiden nicht abhängigen Segmente fungiert. Es gibt nur eine Dateninstanz für dieses Segment. Beide verwaisten Segmente verweisen auf dieses Segment als übergeordnetes Segment. Wenn das übergeordnete Segment fehlt, da es in der Anfrage nicht genannt wurde, wird es bei der Anfrage aktiviert und als übergeordnetes Segment aufgenommen.
Wenn zwei eindeutige Segmente (U) ohne das übergeordnete Segment enthalten sind, werden die eindeutigen Segmente in Segmente mit SEGTYPE S0 umgewandelt, die auf das Systemsegment als übergeordnetes Segment verweisen.
Die Strukturen JOIN und JOIN WHERE werden unterstützt.

Hinweise zur SQL-Optimierung

Die SQL-Optimierung für Summierungen muss für EXTRACT-Anfragen ausgeschaltet werden.

BY/ACROSS/FOR-Hinweise

BY- und ACROSS-Sortierfelder werden zu zusätzlichen Anzeigeobjekten.
BY. . .ROWS und ACROSS . . .COLUMNS werden nur als implizite WHEREs eingesetzt, um enthaltene Feldwerte zu beschränken.
FOR-Felder sind enthalten.
RECAP-Felder sind ausgeschlossen (wie COMPUTEs).
Summierungsfelder, die auf zuvor identifizierte Felder verweisen, werden bei der Erstellung von strukturierte HOLD-Dateien ignoriert. Dazu gehören: SUMMARIZE, RECOMPUTE, SUBTOTAL, SUB-TOTAL ACROSS-TOTAL, ROW-TOTAL und COLUMN-TOTAL.

Hinweise zur Formatierung

Bei der Verarbeitung von strukturierten HOLD-Dateien werden alle Formatierungselemente ignoriert, einschließlich: IN, OVER, NOPRINT, SUP-PRINT, FOLD-LINE, SKIP-LINE, UNDER-LINE, PAGE-BREAK, TABPAGENO, AS und die Ausrichtung von Spaltentiteln. Es sind jedoch Felder enthalten, auf die in Formatierungsbefehlen verwiesen wird (wie HEADING, FOOTING, SUBHEAD und SUBFOOT, sowie alle zugehörigen WHEN-Formeln).
Alle STYLE- und STYLESHEET-Befehle werden bei der Erzeugung von extrahierten Ausgaben ignoriert.
AnV- und AnW-Felder werden unterstützt. TX-Felder werden nur in FOCUS-Dateien exportiert.
Falls FIELDNAME und ALIAS für ein reales Feld gleich sind, und dieses Feld als es selbst neudefiniert wurde (möglicherweise in einem anderen Format), werden zwei Felder mit identischen Feldnamen und Aliasen in der HOLD-Masterdatei erstellt. In diesem Fall kann auf die zweite Version des Feldes nie zugegriffen werden, wenn auf sie mit dem Namen verwiesen wird. Sie können FIELDS=EXPLICIT verwenden, um nur die zweite Version des Feldes aufzunehmen. Der folgende DEFINE veranschaulicht, wie es zu einem duplizierten Feldnamen und Alias kommen kann:
```
DEFINE FILE CAR
COUNTRY/A25=COUNTRY;
END
```

DBA-Hinweise

DBA-Steuerungen in Quelldateien werden beachtet, wenn Anfragen an strukturierte HOLD-Dateien ausgeführt werden, mit Ausnahme von RESTRICT=NOPRINT, wobei Felder, die in einer Anfrage benannt werden, nicht angezeigt werden (diese Felder können nicht exportiert werden und sollten explizit EXCLUDED werden).
DBA-Einschränkungen werden von der HOLD-Masterdatei nicht übernommen.

Extrahierungsdateien wiederherstellen

Sie verwenden dieselbe Syntax, die zur Erzeugung der strukturierten HOLD-Datei verwendet wurde, um eine FOCUS-Datei oder eine Flatfile aus einer strukturierten HOLD-Datei wiederherzustellen. Es muss die ON TABLE SET EXTRACT-Syntax verwendet werden, um Mehrpfadstrukturen beizubehalten.
Alle wiederhergestellten FOCUS-Segmente sind SEGTYPE=S0, da weder KEY- noch INDEX-Informationen beibehalten werden. Ein INDEX kann mit REBUILD INDEX eingefügt werden.