Using PDF Display Format
|
In this section: |
You can display a report as a PDF document. PDF (Adobe Acrobat Portable Document Format) supports most StyleSheet attributes, allowing for full report formatting. The wide range of StyleSheet features supported for PDF are described throughout this documentation.
PDF prints and displays a document consistently, regardless of the application software, hardware, and operating system used to create or display the document.
The report opens in Adobe Acrobat or Acrobat Reader within a web browser. To display a PDF report, a computer must have Adobe Acrobat Reader installed. For free downloads of Acrobat Reader, go to http://www.adobe.com.
Limit: Adobe Acrobat PDF format limits the number of pages, hyperlinks, and images in a document. For information about what limits this creates for a FOCUS report in PDF format, see Saving and Reusing Your Report Output.
Other print-oriented display formats. You can also display a report as a PostScript document. For more information, see Using PostScript (PS) Display Format.
Displaying Watermarks in PDF Output
|
In this section: |
|
Reference: |
Watermarks are images or text strings that are placed on the bottom layer of a document and displayed through the transparent layered content.
FOCUS backcolor does not support transparency. Therefore, standard images placed below it on the page may be obscured. To resolve this, in PDF reports, FOCUS mirrors the approach taken by standard printers, and places an opaque image on the top of the document layers. With this approach, the layers of the document will be visible beneath the transparent watermark image.
Watermark images are provided by the report developer. When creating a transparent image, the image needs to be created in GIF format with a transparent background.
Reference: Inserting Images in PDF Reports With Backcolor
Watermarks are supported for PDF output in compound reports and in single TABLE requests. Each document supports a single active watermark image. This image is designated as the watermark image, by defining the placement order within the Z-INDEX attribute.
The first image with a Z-INDEX value will be considered the active watermark for the current document. Any subsequent images, defined with style sheet attributes for Z-INDEX or OPACITY, will be displayed as standard FOCUS images.
Watermark images are designated by defining the following attributes in the style sheet for the transparent GIF.
|
Z-INDEX=TOP |
Designates that the image is to be handled as a watermark image and should always be placed on top of all other objects on the page. This value will be respected as the topmost layer and will be supported with other layers in future releases. |
|
OPACITY=n |
Where n represents the percent (%) of OPACITY to be applied to the image. The greater the OPACITY, the less transparent the image. Less of the underlying report will be visible below the image. The value for n can be any number from 0 through 100. If a value is not specified, it defaults to 100%, presenting a fully opaque image. |
Within a single TABLE request:
TYPE=<REPORT|HEADING>, OBJECT=IMAGE, IMAGE=<image.gif>, Z-INDEX=TOP, OPACITY=15, POSITION=(.25 .25), DIMENSION=(8 10.5),$
Example: Inserting Transparent Images Into a PDF Report
The following request against the GGSALES data source places the coffee image (coffee.gif) on the page and layers the watermark image (internalonlyport.gif) on top. These images are displayed on every page of the report.
TABLE FILE GGSALES
SUM
GGSALES.SALES01.DOLLARS/D12CM
GGSALES.SALES01.UNITS/D12C
GGSALES.SALES01.BUDDOLLARS/D12CM
GGSALES.SALES01.BUDUNITS/D12C
BY GGSALES.SALES01.REGION
BY GGSALES.SALES01.CATEGORY
BY GGSALES.SALES01.PRODUCT
HEADING
"Gotham Grinds"
"Product Sales By Region"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE HOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
TOPMARGIN=.5,
BOTTOMMARGIN=.5,
LEFTMARGIN=1,
RIGHTMARGIN=1,
$
TYPE=REPORT,
OBJECT=IMAGE,
IMAGE=internalonlyport.gif,
POSITION=(+0.70000 +0.70000),
SIZE=(7 7.5),
Z-INDEX=TOP, OPACITY=15,
$
TYPE=REPORT,
OBJECT=IMAGE,
IMAGE=coffee.gif,
POSITION=(+1.0 +0.5),
SIZE=(.5 .5),
$ENDSTYLE
END
The output is:
Features Supported
The following core PDF features are supported with watermarks:
- Standard TABLE requests, including reports with paneling
- Compound syntax (OPEN/CLOSE)
- Drillthrough
- Bookmarks
- Borders/backcolor
Limits
- OPACITY must be between 0 and 100, inclusive.
- A single watermark image is supported for a single document.
Usage Notes
- For compound syntax, the watermark image must be in the first report. If it is not in the first report, a FOC3362 message is generated.
- The embedded PDF viewer for a browser may not display NLS characters correctly. If NLS characters do not display correctly, use font embedding, as described in Adding PostScript Type 1 Fonts for PS and PDF Formats, or configure your browser to use Adobe Reader.
WebFOCUS PDF Report Accessibility Support
|
In this section: |
WebFOCUS PDF report accessibility provides support for assistive technologies, such as screen readers.
Note: For information on accessibility principles and font types and usage, see the WebAIM website at https://webaim.org/techniques/fonts/#intro.
WebFOCUS PDF report output complies with accessibility requirements as a result of the following features:
- A SET command that activates accessibility changes to WebFOCUS PDF output code.
- As of Release 8206, a DisplayOn=DOC-HEADING StyleSheet attribute that identifies the main document heading in a compound
report.
- In a single standalone report (non-compound document), the first ON TABLE SUBHEAD string is automatically tagged as <H1>. Other page headings and footings, as many as there are available, are tagged as <H2>.
- In a compound report, the DisplayOn=DOC-HEADING attribute should be added to a single fixed-positioned component that will contain the ON TABLE SUBHEAD string. The DOC-HEADING attribute indicates that the ON TABLE SUBHEAD string entered in the fixed-positioned component will be tagged as <H1> and represent the main document heading, which will be displayed once on the first physical page of the document. Other page headings and footings, as many as there are available, are tagged as <H2>.
- A USEASTITLES StyleSheet attribute that places and aligns custom column titles in a heading.
- A BOOKMARK StyleSheet attribute that enables you to go directly to a destination in a document.
- An ALT StyleSheet attribute that describes an image embedded in a report.
- An ALT StyleSheet attribute that provides a description of a drill-down component.
- A LANG attribute that identifies the default language of the document.
- Report output, with the SET ACCESSPDF command enabled, is created with BYDISPLAY=ON, which produces a value in each cell for sort (BY) fields.
Note: It is the responsibility of the report developer to follow general accessibility standards in order for the report to be 508 compliant.
Controlling PDF Code For Accessibility
|
How to: |
The SET ACCESSPDF command enables accessibility for PDF reports.
Syntax: How to Control PDF Code Accessibility
- For all requests in a procedure or in a profile:
SET ACCESSPDF = {508|OFF} - For a single request:
ON TABLE SET ACCESSPDF {508|OFF}
where:
- 508
-
Generates a PDF file compliant with Section 508 accessibility requirements.
- OFF
-
Generates a PDF file that is non-compliant with Section 508 accessibility requirements. This value is the default.
Example: Controlling PDF Code for Accessibility
The following request generates accessible PDF report output. The SET and SUBHEAD commands that enable accessibility appear in boldface.
TABLE FILE GGSALES SUM DOLLARS/D12M BY REGION BY CATEGORY ON REGION SUBTOTAL AS 'Total for ' HEADING " " "Sales Report" " " ON TABLE SET ACCESSPDF 508 ON TABLE SET PAGE-NUM OFF ON TABLE COLUMN-TOTAL AS 'Grand Total' ON TABLE SUBHEAD "Regional Totals by Category" ON TABLE PCHOLD FORMAT PDF ON TABLE SET STYLE * TYPE=REPORT, FONT='ARIAL',$ TYPE=TITLE, COLUMN=N1, FONT='ARIAL', STYLE=BOLD,$ TYPE=TITLE, COLUMN=N2, FONT='ARIAL', STYLE=BOLD,$ TYPE=TITLE, COLUMN=N3, FONT='ARIAL', STYLE=BOLD,$ TYPE=HEADING, SIZE=14, STYLE=BOLD,$ TYPE=TABHEADING, SIZE=16, STYLE=BOLD,$ TYPE=SUBTOTAL, BY=1, STYLE=BOLD,$ TYPE=GRANDTOTAL, FONT='ARIAL', STYLE=BOLD,$ ENDSTYLE END
WebFOCUS generates the following tags when SET ACCESSPDF is set to 508.
Page Heading
Heading tags <H1> and <H2> and are automatically generated by WebFOCUS.
Column Titles
Row tags <TR> and header cell tags <TH> are generated by WebFOCUS. The column title is aligned with the appropriate data columns.
Data Cells
Row tags <TR> and header cell tags <TH> are generated by WebFOCUS.
The output is:
Aligning Elements in a Page Heading With Column Data
|
How to: |
The USEASTITLES StyleSheet attribute for PDF reports enables you to place and align custom column titles (AS='text') in the heading, rather than use the default column titles. The USEASTITLES attribute associates column titles in the heading with the appropriate data column.
Syntax: How to Align Elements in a Page Heading With Column Data
TYPE=HEADING, USEASTITLES=ON, HEADALIGN=BODY,$
USEASTITLES=ON can only be set for the entire HEADING. HEADALIGN=BODY must also be set for the HEADING.
To use this attribute in App Studio:
- The Report Output Format is PDF.
- The Alignment Grid is enabled for the Page Heading.
- Add a Page Heading to the report.
- Right-click the Page Heading and select Alignment Grid.
- On the Insert Alignment Grid dialog box, select the Align with Data option and click OK.
- In the Page Heading, right-click the alignment grid and select Align column title (Section 508).
Example: Aligning Elements in a Page Heading to Column Data
The USEASTITLES attribute that enables the alignment of the heading elements is in bold. Note that the HEADALIGN=BODY attribute is also in bold.
TABLE FILE GGSALES
SUM
DOLLARS/D12M AS ''
BY REGION AS ''
BY CATEGORY AS ''
ON REGION SUBTOTAL AS 'Total for '
HEADING
" "
"Sales Report"
" <+0> <+0> "
"Region<+0>Category<+0>Dollar Sales"
ON TABLE SET ACCESSPDF 508
ON TABLE SET PAGE-NUM OFF
ON TABLE COLUMN-TOTAL AS 'Grand Total'
ON TABLE SUBHEAD "Regional Totals by Category <+1"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
$
TYPE=REPORT, FONT='ARIAL',$
TYPE=TITLE, COLUMN=N1, FONT='ARIAL', STYLE=BOLD,$
TYPE=TITLE, COLUMN=N2, FONT='ARIAL', STYLE=BOLD,$
TYPE=TITLE, COLUMN=N3, FONT='ARIAL', STYLE=BOLD,$
TYPE=HEADING, SIZE=14, STYLE=BOLD,
HEADALIGN=BODY, USEASTITLES=ON,$
TYPE=HEADING, LINE=2, OBJECT=TEXT, ITEM=1, COLSPAN=3, JUSTIFY=LEFT,$
TYPE=HEADING, LINE=3, OBJECT=TEXT, ITEM=1, COLSPAN=1, JUSTIFY=LEFT,$
TYPE=HEADING, LINE=3, OBJECT=TEXT, ITEM=2, SIZE=10, COLSPAN=1,
JUSTIFY=RIGHT,$
TYPE=HEADING, LINE=3, OBJECT=TEXT, ITEM=3, SIZE=10, COLSPAN=1,
JUSTIFY=RIGHT,$
TYPE=HEADING, LINE=4, OBJECT=TEXT, ITEM=1, SIZE=11, COLSPAN=1,
JUSTIFY=LEFT,$
TYPE=HEADING, LINE=4, OBJECT=TEXT, ITEM=2, SIZE=11, COLSPAN=1,
JUSTIFY=LEFT,$
TYPE=HEADING, LINE=4, OBJECT=TEXT, ITEM=3, SIZE=11, COLSPAN=1,
JUSTIFY=RIGHT,$
TYPE=TABHEADING, SIZE=16, STYLE=BOLD,$
TYPE=SUBTOTAL, BY=1, STYLE=BOLD,$
TYPE=GRANDTOTAL, FONT='ARIAL', STYLE=BOLD,$
ENDSTYLE
ENDWebFOCUS generates the following tags when the USEASTITLES attribute is used.
Page Heading and Column Titles
Row tags <TR> and header cell tags <TH> are generated by WebFOCUS. Along with the Page Heading, the column titles are also tagged as header cells <TH>.
The output is:
Adding Bookmarks
Bookmarks are links in the navigation pane that enable you to go directly to a destination in the document. Using bookmarks enables you to jump from the tagged items in the navigation pane directly to the page where the item is located. The benefit of using bookmarks in conjunction with a screen reader is that you will be able to navigate a defined hierarchy without having to listen to the reading of the entire document. For more information about navigating PDF Bookmarks, see the Adobe documentation on the Adobe Web site, www.adobe.com.
Note:
- Since a PDF document is a complete file, you can use bookmarks and scrolling to navigate through the file. You can easily navigate through a document, especially documents that are two or more pages in length.
- You can generate bookmarks within WebFOCUS by including the BOOKMARKS and/or TOC object in the compound layout syntax. Then, in the component definitions, specify the Table of Contents level and description. You can also optionally specify the BYTOC levels.
- For 508 compliance, it is recommended that the Bookmark object be used.
Example: Adding Bookmarks to the Compound Layout
The BOOKMARK attribute that enables the alignment is in bold. The TOC-LEVEL=1 and BYTOC=2 attributes for both reports are also in bold. These attributes are explained below:
- TOC-LEVEL=n
Defines n as the Table of Contents level for the report layout object. This option defines the hierarchical order of objects within the Table of Contents.
0 = the object is not shown in the Table of Contents.
1 = the object is shown as a first-level item in the Table of Contents.
2 = the object is shown as a second-level item in the Table of Contents, and so on.
- BYTOC=m
Specifies the number of BY fields to be included within the current component entry (m).
The following request adds bookmarks and specifies the main document heading for the compound report. The report0 component uses the DisplayOn=DOC-HEADING attribute to indicate that the ON TABLE SUBHEAD string from the report0 component should be tagged as the main document heading in the PDF output.
SET ACCESSPDF = 508 COMPOUND LAYOUT PCHOLD FORMAT PDF OBJECT=BOOKMARKS,$ SECTION=S1, LAYOUT=ON, MERGE=OFF, ORIENTATION=PORTRAIT,$ PAGELAYOUT=1,$ COMPONENT=report0, position=(1 0.5), Dimension=(* *), DisplayOn=DOC-HEADING, $ COMPONENT=report1, TEXT='This is the Title for Report 1', TOC-LEVEL=1, BYTOC=2, POSITION=(1 1), DIMENSION=(* *),$ COMPONENT=report2, TEXT='Sales By Region', TOC-LEVEL=1, BYTOC=2, POSITION=(+0.00 +0.519), DIMENSION=(* *), RELATIVE-TO='report1', REQUIRED-SPACE=(*3.5), RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,$ END
SET COMPONENT=report0 TABLE FILE GGSALES BY CATEGORY NOPRINT ON TABLE SUBHEAD " " "DOLLAR SALES REPORT" " " " " ON TABLE SET PAGE-NUM OFF ON TABLE HOLD FORMAT PDF ON TABLE SET STYLE * TYPE=TABHEADING , SIZE=18, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$ ENDSTYLE END SET COMPONENT=report1 TABLE FILE GGSALES SUM DOLLARS/F8M BY CATEGORY BY PRODUCT BY REGION BY ST ON CATEGORY PAGE-BREAK WHERE PRODUCT NE 'Capuccino' ON CATEGORY SUBTOTAL AS 'Subtotal for: ' HEADING "Sales by Category" " " ON TABLE HOLD FORMAT PDF ON TABLE SET PAGE-NUM OFF ON TABLE NOTOTAL ON TABLE SET STYLE * TYPE=REPORT, SIZE=10, FONT=ARIAL,$ TYPE=HEADING, SIZE=14, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$ TYPE=SUBTOTAL, SIZE=10, STYLE=BOLD,$ ENDSTYLE END
SET COMPONENT=report2 TABLE FILE GGSALES SUM DOLLARS/F8M BY REGION BY ST BY CATEGORY BY PRODUCT ON REGION PAGE-BREAK WHERE PRODUCT NE 'Capuccino' ON REGION SUBTOTAL AS 'Subtotal for: ' HEADING "Sales by Region" " " ON TABLE HOLD FORMAT PDF ON TABLE SET PAGE-NUM OFF ON TABLE NOTOTAL ON TABLE SET STYLE * TYPE=REPORT, SIZE=10, FONT=ARIAL,$ TYPE=HEADING, SIZE=14, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$ TYPE=SUBTOTAL, SIZE=10, STYLE=BOLD,$ ENDSTYLE END COMPOUND END
The report output, with bookmarks, is shown below.
Notice that the hierarchy tree in the Bookmarks pane has two levels for each report and is determined with the BYTOC attribute. The title for each report in the Bookmarks tree is determined with the TEXT attribute, as shown in the following image.
The first three pages of the PDF output, with the Tags panel, are shown in the following images. Note that only the first page of output contains the <H1> heading, DOLLAR SALES REPORT. The other headings are tagged as <H2>.
Page 1
Page 2
Page 3
Adding Descriptive Text to an Image
|
How to: |
The ALT attribute in a WebFOCUS StyleSheet adds descriptive text to an embedded image in a PDF report. The ALT attribute in the StyleSheet generates a PDF ALT attribute on the <IMG> tag.
The ALT tag is displayed in the PDF when you hover the mouse over the image.
Procedure: How to Add Descriptive Text to an Image
ALT='description'
where:
- description
-
Is a brief description of the image, enclosed in single quotation marks (‘). The length can be a maximum of 256 characters.
For details on the StyleSheet syntax for adding an image, see the Creating Reports With WebFOCUS Language manual.
Example: Adding Descriptive Text to an Image
This request adds the Information Builders logo to a report heading. It uses the WebFOCUS StyleSheet ALT attribute to add descriptive text (Information Builders logo) that identifies the image.
TABLE FILE GGSALES
SUM
DOLLARS/D12N
BY REGION
BY CATEGORY
ON REGION SUBTOTAL AS 'Total sales: '
ON REGION PAGE-BREAK
HEADING
"Sales Report"
" "
" "
ON TABLE SET ACCESSPDF 508
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SUBHEAD "Regional Totals by Category"
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT, GRID=OFF, FONT='ARIAL', SIZE=9,$
TYPE=TITLE, STYLE=BOLD,$
TYPE=HEADING, SIZE=12, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=TABHEADING, SIZE=14, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=SUBTOTAL, BACKCOLOR=RGB(210 210 210), STYLE=BOLD,$
TYPE=REPORT, IMAGE=smplogo1.gif, ALT='Information Builders logo',
POSITION=(1.19 .9), SIZE=(.8 .2),$
ENDSTYLE
END
The report is:
When the request is run, hovering the mouse over the image displays the descriptive text. This text is read by accessibility tools, such as JAWS.
Describing Drill Down Information
|
How to: |
When ACCESSPDF is enabled, the developer can provide a description of the Drill Down using the ALT attribute in a WebFOCUS StyleSheet. In the PDF report, JAWS will read the value of the Drill Down component along with the ALT text.
Including a description of the detail component of a Drill Down report supports accessibility.
Syntax: How to Add Descriptive Drill Down Information
ALT='description'
where:
- description
-
Is the description of the Drill Down information in a report, enclosed in single quotation marks (‘). The length can be a maximum of 256 characters.
For details on the StyleSheet syntax for Drill Down reports, see the Creating Reports With WebFOCUS Language manual.
TABLE FILE GGSALES
SUM
DOLLARS/D12N
BY REGION
BY CATEGORY
ON REGION SUBTOTAL AS 'Total sales: '
HEADING
" "
ON TABLE SET ACCESSPDF 508
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SUBHEAD "Sales Report"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
SUMMARY='508 Sales report example',
TITLETEXT='508 Sales report example',
$
TYPE=REPORT, GRID=OFF, FONT='ARIAL', SIZE=9,$
TYPE=DATA, COLUMN=N2,
ALT='Drill Down to detail report.', \
FOCEXEC=508drill01detail( REGION=N1 CATEGORY=N2 ),$
TYPE=TITLE, STYLE=BOLD,$
TYPE=TABHEADING, SIZE=12, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=HEADING, SIZE=12, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=SUBTOTAL, BACKCOLOR=RGB(210 210 210), STYLE=BOLD,$
ENDSTYLE
END
Note the ALT attribute and associated text in BOLD.
The report is:
When you hover the mouse over Coffee for the Midwest region, the URL information for the Drill Down appears in the box. Screen readers, such as JAWS, will not read hover text. With ACCESSPDF enabled, the ALT text or 'Drill Down to detail report' is appended to the value for the Drill Down or 'Coffee' in this example. When you navigate to Coffee, the screen reader will respond with Coffee Drill Down to detail report.
Note:
- Users that use screen readers, such as JAWS, may need more information regarding the Drill Down link. In the above example, notice that there are multiple hyperlinks for the value Coffee. This functionality, along with the 'read current cell' command, allows the user to understand the difference in those values. The screen reader command to 'read current cell' in JAWS is the Ctrl+Alt+Num5 shortcut. In this example, JAWS would respond to the 'read current cell' command with column two, row two, region Midwest, link Coffee Drill Down to detail report.
- If you are opening the output in Adobe Reader, make sure you specify the FOCEXURL setting to provide the URL context of the
WebFOCUS environment the Drill Down is to call back to. In addition, the FOCEXURL value has to have the parameter to specify
that the request is a Drill Down request. For example:
-SET &FOCEXURL='http://host:port/ibi_apps/WFServlet?IBIF_webapp= /ibi_apps' | '&'; -SET &FOCEXURL=&FOCEXURL | 'IBIMR_drill=IBFS,RUNFEX,IBIF_ex,true' | '&'; -SET &FOCEXURL=&FOCEXURL | 'IBIC_server=EDASERVE' | '&'; -SET &FOCEXURL=&FOCEXURL | 'IBIAPP_app=ibisamp' | '&'; SET FOCEXURL='&FOCEXURL'
Accessibility Limitations
Reports using the following elements are not accessible:
- If a procedure does not contain the SET PAGE-NUM=OFF or ON TABLE SET PAGE-NUM OFF command, the page number will be announced two times by the screen reader.
- ACROSS and OVER reports.
- Financial Modeling Language (FML).
- FOLD-LINE. Accessibility is disabled when FOLD-LINE is used in a report.
- Fixed monetary edit options (N, !d, !e, !l and !y) including the Credit Negative (CR). A unique cell is created for the noted monetary options or CR option.
- Text included or designed in FOOTING, SUBHEAD, SUBFOOT, RECAP, SUMMARIZE, and RECOMPUTE commands do not generate row header tags.
