How to: Reference: |
The TYPE statement either appears on the terminal or stores in a sequential file messages that you prepare. This section describes:
- The syntax of the TYPE statement.
- Use of embedded data fields.
- Use of spot markers.
- Use of extended attributes.
Note: Text fields cannot be used with the TYPE statement.
The syntax of the TYPE statement is
TYPE [AT START|AT END] [ON ddname] "message" ["message"]
where:
- AT START
-
Displays a message at the beginning of execution only.
- AT END
-
Displays a message at the end of execution only. If you are using Case Logic, the TYPE AT END statement must be in the case that generates the end-of-file condition. Either the case must include a FIXFORM or FREEFORM statement that will reach the end of the transaction data source; or a PROMPT statement, at which the user will type END or QUIT; or a CRTFORM statement, at which the user will type END or press the PF3 key.
- ON ddname
-
Writes the message to a sequential file allocated to ddname. The TYPE statement can write lines of up to 256 characters each, including blanks and embedded field values. If you omit this phrase, the request displays the message on the terminal.
- message
-
Is any message. Enclose each line in double quotation marks (except when you want to display two lines as one line, as described later in this section in Embedding Spot Markers.) If you are displaying messages at the terminal, the lines begin in column 2 on the screen. If you are writing the message to a file, the lines begin in column 3 in the file. You may embed spot markers and data fields in the message.
Note that you can type the TYPE statement on one line. For example:
TYPE "THIS IS A ONE LINE MESSAGE"
TYPE statements can stand by themselves, they can be part of MATCH and NEXT statements, and they can follow VALIDATE statements. For example:
MODIFY FILE EMPLOYEE TYPE " " "PLEASE ENTER THE FOLLOWING DATA" " " PROMPT EMP_ID CURR_SAL MATCH EMP_ID ON NOMATCH REJECT ON MATCH UPDATE CURR_SAL DATA
This request asks the user to enter data at the beginning of every transaction. Note that there is a blank message line both before and after the message "PLEASE ENTER THE FOLLOWING DATA:" This enhances readability and appearance.
TYPE statements may be part of MATCH and NEXT statements. For example, this request warns the user when an employee ID that the user has entered is not in the data source:
MODIFY FILE EMPLOYEE
PROMPT EMP_ID CURR_SAL
MATCH EMP_ID
ON MATCH UPDATE CURR_SAL
ON NOMATCH TYPE
" "
"NO SUCH EMPLOYEE IN THE DATABASE"
"PLEASE RETYPE THE EMPLOYEE ID"
ON NOMATCH REJECT
DATATYPE statements can display messages when incoming data values fail validation tests, as discussed in Validating Transaction Values: The VALIDATE Statement. For example, this request warns the user when a salary higher than $50,000 is entered:
MODIFY FILE EMPLOYEE
PROMPT EMP_ID CURR_SAL
VALIDATE
SALTEST = IF CURR_SAL LE 50000 THEN 1 ELSE 0;
ON INVALID TYPE
" "
"THE CURR_SAL VALUE IS OVER 50000"
"AND THEREFORE CANNOT BE ENTERED INTO THE"
"DATABASE. PLEASE NOTIFY YOUR SUPERVISOR."
MATCH EMP_ID
ON MATCH UPDATE CURR_SAL
ON NOMATCH REJECT
DATANote that ON INVALID TYPE phrases can occur after VALIDATE statements that stand by themselves or are part of MATCH statements. For example:
MATCH PAY_DATE
ON NOMATCH REJECT
ON MATCH VALIDATE
GROSS_TEST = IF GROSS LT 1500 THEN 1 ELSE 0;
ON INVALID TYPE
"GROSS OVER $1500. PLEASE REENTER"
You can embed data fields in the middle of messages. Embedded data fields are described in the Creating Reports manual. The kind of field you may embed depends on the position of the TYPE statement:
- TYPE statements preceding MATCH or NEXT statements only accept incoming data fields in messages, not data source fields.
- This request
contains a TYPE statement before the MATCH statement:
MODIFY FILE EMPLOYEE FIXFORM EMP_ID/9 X1 CURR_SAL/8 TYPE "EMPLOYEE ID: <EMP_ID SALARY: <CURR_SAL" MATCH EMP_ID ON MATCH UPDATE CURR_SAL ON NOMATCH REJECT DATA ON EMPSAL END
- TYPE phrases in or following a MATCH or NEXT statement accept both incoming data fields and data source fields in messages. The data source field must either be in the segment instance that the MATCH or NEXT statement is modifying or in a parent instance along the segment path (the parent instance, the parent's parent, and so on to the root segment). To specify a data source field, affix the prefix D. to the field name.
This TYPE phrase displays both the incoming value of CURR_SAL and the data source value:
ON MATCH TYPE "SALARY ENTERED IS: <CURR_SAL" "OLD SALARY WAS: <D.CURR_SAL"
You can use embedded fields together in a statement to display a total. This request totals all salaries updated:
MODIFY FILE EMPLOYEE
PROMPT EMP_ID CURR_SAL
MATCH EMP_ID
ON NOMATCH REJECT
ON MATCH COMPUTE
TOTAL_SAL/D10.2 = TOTAL_SAL + CURR_SAL;
ON MATCH UPDATE CURR_SAL
TYPE AT END
"TOTAL OF ALL NEW SALARIES IS <TOTAL_SAL"
DATAEvery time the user enters a salary, the request adds it to the running total TOTAL_SAL. After the user enters the last salary, the request displays the TOTAL_SAL value embedded in the message.
Note: Each line of text can contain up to 256 characters. This includes the lengths of the embedded fields as defined by the display field formats (for example, the CURR_SAL field, having the format D12.2M, takes up 15 characters, including decimal point, commas, and dollar sign).
Embedded fields enable you to design your own log files to record transactions, replacing the automatic log file facility activated by the LOG statement. This request logs accepted transactions into the file ACCFILE and logs rejected transactions into the file REJFILE:
MODIFY FILE EMPLOYEE
PROMPT EMP_ID CURR_SAL
MATCH EMP_ID
ON MATCH TYPE ON ACCFILE
"<EMP_ID <12 <CURR_SAL"
ON MATCH UPDATE CURR_SAL
ON NOMATCH TYPE ON REJFILE
"<EMP_ID <12 <CURR_SAL"
ON NOMATCH REJECT
DATA
This request records in the ACCFILE file the employee ID and new salary entered by the user if the ID is in the data source and records the ID and salary in the REJFILE file if the ID is not in the data source. Note that the spot markers in both TYPE messages ensure that the fields will be aligned in the files, making the files fixed sequential files. If the request logged the transactions using the MODIFY LOG facility, the files would have been comma-delimited because the request uses PROMPT to input data. Note that you must issue an allocation for each log file prior to using it in the MODIFY request.
You can embed spot markers in TYPE statement messages. Spot markers are devices that place message text at different places on the screen. Spot markers are described in Tutorial: Painting a Procedure. Some common spot markers are shown below (where n is an integer):
- <n
-
Places text starting at the nth column.
- <+n
-
Places text n columns to the right.
- </n
-
Places text n lines down.
- <0X
-
Positions the next character immediately to the right of the last character (skip zero columns). This is used when you have two or more lines between the double quotation marks in a procedure that make up a single line of information on a FIDEL screen. No spaces are inserted between the spot marker and the start of a continuation line.
For example, the statement
TYPE "THE DOLLAR SIGN IS IN COLUMN 40: <40 $" "TEN SPACES ARE EMBEDDED <+10 IN THIS LINE" "</1 THIS LINE SKIPS A LINE <0X AND PROVIDES AN EXAMPLE OF THE USE <0X OF A COLUMN MARKER"
produces the following output:
Note: The spot marker to skip a line, </n, can appear on the same line with other text in a TYPE statement. However, in a CRTFORM, this spot marker must appear on a line by itself (see Designing Screens With FIDEL).
Sometimes, a line of text you want displayed cannot fit on one line within the TYPE command. This can occur because you are indenting lines or because there are non-printable characters in the message, such as spot markers and field prefixes. To have two lines in the TYPE statement displayed as one line, do the following:
- End the first line without an end quotation mark.
- Do not begin the second line with a quotation mark. Instead, begin the line with a <+n spot marker where n is any number greater than or equal to zero.
This TYPE statement demonstrates how this feature can be used:
TYPE "<D.FIRST_NAME <D.LAST_NAME EMP. #<EMP_ID <+1 SALARY: <CURR_SAL"
If you enter in the employee ID 123764317 and a salary of $27,000, the request displays this message:
JOAN IRVING EMP. #123764317 SALARY: $27,000.00
You may write a message of several lines this way. Begin the first line of the message with a quotation mark and end the last line with a quotation mark. Begin alternating lines with the <+1 spot marker. This causes the request to display every two lines of text as one line.
For example, if you type this statement in the request:
TYPE "SALARY UPDATE PROCEDURE <+1 WRITTEN JUNE 26, 1985" "ENTER EACH EMPLOYEE ID AND SALARY <+1 AFTER THE PROMPTS"
The request displays the message as:
SALARY UPDATE PROCEDURE WRITTEN JUNE 26, 1985 ENTER EACH EMPLOYEE ID AND SALARY AFTER THE PROMPTS
The following request employs both spot markers and embedded fields in messages:
MODIFY FILE EMPLOYEE
PROMPT EMP_ID
MATCH EMP_ID
ON NOMATCH TYPE
"</1 EMPLOYEE <EMP_ID NOT IN THE DATABASE"
"PLEASE RETYPE NUMBER OR NOTIFY SUPERVISOR"
ON NOMATCH REJECT
ON MATCH TYPE
"</1 EMPLOYEE <15 LAST_NAME <30 FIRST_NAME <45 SALARY"
"</1 <EMP_ID <15 <D.LAST_NAME
"<+1 <30 <D.FIRST_NAME <40 <D.CURR_SAL"
"</1 ENTER SALARY FOR EMPLOYEE <EMP_ID"
" "
ON MATCH PROMPT CURR_SAL
ON MATCH UPDATE CURR_SAL
DATAWhen you run this request, the session looks like this:
> EMPLOYEE ON 10/10/98 AT 19.44.47 DATA FOR TRANSACTION 1 EMP_ID = > 451123478 EMPLOYEE LAST_NAME FIRST_NAME SALARY 451123478 MCKNIGHT ROGER $16,100.00 ENTER SALARY FOR EMPLOYEE 451123478 CURR_SAL = > 18500 DATA FOR TRANSACTION 2 EMP_ID = >
If your request includes CRTFORMs, you can enhance TYPE statements with screen attributes, devices that display a line, part of a line, or an embedded field in color, in reverse video, flashing, or underlined. Screen attributes are discussed in Designing Screens With FIDEL, in connection with the FIDEL facility.
Note the following when using screen attributes in TYPE statements:
- You may use screen attributes only in TYPE statements that follow a CRTFORM and will appear on the screen beneath the CRTFORM during execution.
- Extended attributes
in TYPE statements only work on terminals that can process all screen
attributes. To use screen attributes in TYPE statements, you must
issue the command:
SET EXTTERM = ON
- When you add an attribute to a line, whether you place the attribute before a field or before text, the attribute remains in effect until the end of the line or until the next attribute, whichever comes first.
- Attributes for TYPE statements are cleared at the end of each line. To apply an attribute to a block of text, type the attribute at the beginning of each line.
This request uses attributes in TYPE statements:
MODIFY FILE EMPLOYEE
CRTFORM
"ENTER EMPLOYEE ID: <EMP_ID"
"ENTER SALARY: <CURR_SAL"
MATCH EMP_ID
ON MATCH UPDATE CURR_SAL
ON NOMATCH TYPE
"<.WHITE. EMPLOYEE #<.AQUA.EMP_ID"
"<.WHITE. IS <.RED. NOT <.WHITE. IN THE DATABASE"
"<.WHITE. PLEASE NOTIFY SUPERVISOR"
ON NOMATCH REJECT
DATA
END
The request displays the employee ID in aquamarine and the EMPLOYEE IS NOT IN THE DATABASE message in white, except for the word NOT, which is in red.