Lors de la distribution de rapports contenant des liens hypertexte actifs ou des liens vers des rapports WebFOCUS (dits « zoom en profondeur »), le contexte de l'URL doit être entièrement qualifié et l'utilisateur doit pouvoir se connecter au serveur d'applications ou au serveur Web afin d'exécuter le rapport ou d'accéder au contenu du lien hypertexte. Vous pouvez qualifier entièrement le lien hypertexte à l'aide de la commande SET FOCHTMLURL ou SET BASEURL. Utilisez SET FOCHTMLURL pour accéder aux ressources résidant sous l'alias ibi_apps/ibi_html. Utilisez SET BASEURL dans les procédures non Managed Reporting pour spécifier l'emplacement par défaut d'une adresse URL relative renvoyant à des documents créés par WebFOCUS (fichiers HTML et images). Pour qualifier entièrement le zoom en profondeur, utilisez la commande SET FOCEXURL.

Pour faire un zoom en profondeur sur une procédure du serveur WebFOCUS, il faut inclure la commande suivante dans le code original de la procédure planifiée :

SET FOCEXURL=http://hostname[:port]/wf_context_root/WFServlet;

où :

hostname[:port]

est le nom d'hôte et le numéro et le numéro de port facultatif du serveur d'applications ou Web sur lequel est installé le client WebFOCUS.

wf_context_root

est la racine de contexte adaptée à l'application de WebFOCUS qui est déployée sur votre serveur d'applications. La valeur par défaut est ibi_apps.

L'image ci-après montre un exemple de la commande FOCEXURL dans un FEX.

-* FEX that is scheduled and distributed to the Report Library
-* Set FOCEXURL value for navigation back to WF Client and MR context
-* for execution of drill down request. Must be coded using
-* concatenation of so that WF describe (auto prompting) is not invoked 
-* and also for character encoding within URL to be done correctly.
-* Protocol, host and port to WF client. 
-* Do not use localhost for the host value!
-SET &FOCEXURL='http://host:port';
-*
-* Call to WF Client.  /ibi_apps is the default URL context 
-* but can be customized
-SET &FOCEXURL=&FOCEXURL | '/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps'  '&';
-* If report contains a drilldown the next set of lines are also needed.
-* Set WF Reporting Server to run request on
-SET &FOCEXURL=&FOCEXURL | 'IBIC_server=EDASERVE' | '&';
-*
-* Set whether the message viewer feature is ON or OFF.
-* When message viewer feature is ON the browser window displaying the 
-* report will have multiple frames. The top frame displays 
-* the report and the bottom frame displays any messages returned 
-* from the WF Server from the report execution.
-* Most often utilized during report development or to debug a problem.
-SET &FOCEXURL=&FOCEXURL | 'IBIWF_msgviewer=OFF' | '&';
-*
-* IBIMR_drill tells WF client subsequent request is a drill down and the 
-* information after X, is the HREF of the MR domain that the 
-* drill down FEX
-* is located in. In this example 'salesrpt' is the internal 
-* domain directory and salesrpt.htm is the HTML file 
-* containing the metadata information for the contents
-* within the salesrpt domain.
-SET &FOCEXURL=&FOCEXURL | 'IBIMR_drill=X,salesrpt/salesrpt.htm'| '&';
-*
-* SET environmental variable FOCEXURL

SET FOCEXURL='&FOCEXURL'
-*
TABLE FILE CAR
SUM CAR.BODY.SALES
BY CAR.ORIGIN.COUNTRY
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=CAR.ORIGIN.COUNTRY,
 FOCEXEC=salesrpt/app/carmodel.fex,
 $
ENDSTYLE
ON TABLE SET HTMLCSS ON
ON TABLE NOTOTAL
END

Voici un exemple du zoom en profondeur FEX qui réside dans Managed Reporting.

-* HTML Tool
-* Created by Report Assistant
-* FF Line do not change this line! Field Name
-* FF Line do not change this line! Alias
-* FF Line do not change this line! Format
-* FF Line do not change this line! Segment
-* FF Line do not change this line! displayTree=0
TABLE FILE CAR
SUM CAR.SPECS.MPG
CAR.SPECS.RPM
CAR.BODY.SEATS
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
BY CAR.BODY.BODYTYPE
ON TABLE SET HTMLCSS ON
ON TABLE NOTOTAL
END
-* End Report Assistant