x

Al distribuir informes que contengan vínculos activos o vínculos a informes de WebFOCUS (drill downs), el contexto de URL debe estar completamente cualificado y el usuario debe tener conexión a un servidor web o de aplicaciones, para poder ejecutar el informe a acceder al contenido del vínculo. Puede calificar completamente el vínculo activo usando los comandos SET FOCHTMLURL o SET BASEURL. Use SET FOCHTMLURL para acceder a recursos que residen bajo el alias ibi_apps/ibi_html. En el caso de procedimientos que no sean de Managed Reporting, use SET BASEURL para especificar una ubicación predeterminada para un URL relativo, que haga referencia a documentos (archivos HTML e imágenes) creados por WebFOCUS. Puede calificar completamente el drill down mediante el comando SET FOCEXURL.

Principio de página

Ejemplo: Cómo usar SET FOCEXURL para profundizar hasta un procedimiento de WebFOCUS Managed Reporting

Para hacer drill down a un procedimiento de servidor de WebFOCUS, el procedimiento original que programe debe incluir el siguiente comando:

SET FOCEXURL=http://hostname[:port]/wf_context_root/WFServlet;

donde:

hostname[:port]

Es el nombre del host y el número del puerto opcional del servidor web o de aplicaciones en que se ha instalado el Cliente WebFOCUS.

wf_context_root

Es la raíz de contexto de sitio personalizado para la aplicación web de WebFOCUS implementada en su servidor de aplicación. El valor predeterminado es ibi_apps.

A continuación se muestra un ejemplo del comando FOCEXURL en un FEX.

-* FEX that is scheduled and distributed to the Report Library
-* Set FOCEXURL value for navigation back to WF Client and MR context
-* for execution of drill down request. Must be coded using
-* concatenation of so that WF describe (auto prompting) is not invoked 
-* and also for character encoding within URL to be done correctly.
-* Protocol, host and port to WF client. 
-* Do not use localhost for the host value!
-SET &FOCEXURL='http://host:port';
-*
-* Call to WF Client.  /ibi_apps is the default URL context 
-* but can be customized
-SET &FOCEXURL=&FOCEXURL | '/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps'  '&';
-* If report contains a drilldown the next set of lines are also needed.
-* Set WF Reporting Server to run request on
-SET &FOCEXURL=&FOCEXURL | 'IBIC_server=EDASERVE' | '&';
-*
-* Set whether the message viewer feature is ON or OFF.
-* When message viewer feature is ON the browser window displaying the 
-* report will have multiple frames. The top frame displays 
-* the report and the bottom frame displays any messages returned 
-* from the WF Server from the report execution.
-* Most often utilized during report development or to debug a problem.
-SET &FOCEXURL=&FOCEXURL | 'IBIWF_msgviewer=OFF' | '&';
-*
-* IBIMR_drill tells WF client subsequent request is a drill down and the 
-* information after X, is the HREF of the MR domain that the 
-* drill down FEX
-* is located in. In this example 'salesrpt' is the internal 
-* domain directory and salesrpt.htm is the HTML file 
-* containing the metadata information for the contents
-* within the salesrpt domain.
-SET &FOCEXURL=&FOCEXURL | 'IBIMR_drill=X,salesrpt/salesrpt.htm'| '&';
-*
-* SET environmental variable FOCEXURL

SET FOCEXURL='&FOCEXURL'
-*
TABLE FILE CAR
SUM CAR.BODY.SALES
BY CAR.ORIGIN.COUNTRY
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=CAR.ORIGIN.COUNTRY,
 FOCEXEC=salesrpt/app/carmodel.fex,
 $
ENDSTYLE
ON TABLE SET HTMLCSS ON
ON TABLE NOTOTAL
END

A continuación, un ejemplo del drill-down FEX que reside en Managed Reporting.

-* HTML Tool
-* Created by Report Assistant
-* FF Line do not change this line! Field Name
-* FF Line do not change this line! Alias
-* FF Line do not change this line! Format
-* FF Line do not change this line! Segment
-* FF Line do not change this line! displayTree=0
TABLE FILE CAR
SUM CAR.SPECS.MPG
CAR.SPECS.RPM
CAR.BODY.SEATS
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
BY CAR.BODY.BODYTYPE
ON TABLE SET HTMLCSS ON
ON TABLE NOTOTAL
END
-* End Report Assistant